PST ဖိုင်တစ်ခုရှိ ဖိုင်တွဲအားလုံး၏ အရွယ်အစား အချက်အလက်ကို Excel ဖိုင်တစ်ခုသို့ အမြန်တင်ပို့နည်း

PST ဖိုင်တစ်ခုရှိ ဖိုဒါတစ်ခုစီ၏ အရွယ်အစား အချက်အလက်ကို စစ်ဆေးလိုပါက၊ ဤဆောင်းပါးတွင် ဖော်ပြထားသော နည်းလမ်းကို အသုံးပြုနိုင်သည်။ ၎င်းသည် PST ဖိုင်ရှိ ဖိုင်တွဲအားလုံး၏ အရွယ်အစား အချက်အလက်ကို Excel ဖိုင်သို့ လျင်မြန်စွာ တင်ပို့ပေးမည်ဖြစ်သည်။

သင်၏ PST ဖိုင်သည် ကြီးလွန်းသောအခါ၊ ဖိုင်တစ်ခုစီ၏ အရွယ်အစားကို သင်စစ်ဆေးလိုပေမည်။ ၎င်းသည် သင့်အား မည်သည်ပိုကြီးသည်ကို အလွယ်တကူ ရှာဖွေနိုင်ပြီး အရွယ်အစားအလိုက် သင့်လျော်သော မှတ်တမ်းများကို ပြုလုပ်နိုင်စေရန် ကူညီပေးပါမည်။ ယေဘုယျအားဖြင့်၊ ဖိုဒါအရွယ်အစားကို စစ်ဆေးရန်၊ သင်သည် ဖိုင်တွဲတစ်ခုပေါ်တွင် ညာဖက်ကလစ်နှိပ်ပြီးနောက် “Properties” ကို ရွေးချယ်နိုင်သည်။ ပေါ်လာသော ဒိုင်ယာလော့ဂ်ဘောက်စ်အသစ်တွင်၊ သင်သည် “ဖိုင်တွဲအရွယ်အစား” ခလုတ်ကို နှိပ်နိုင်သည်။ သို့သော်၊ သင်သည် ဖိုင်တွဲများစွာကို ဖန်တီးထားပါက၊ အရွယ်အစား အချက်အလက်ကို တစ်ပုံချင်းစီ ကိုယ်တိုင်စစ်ဆေးခြင်းသည် အတော်အတန် ဒုက္ခရောက်ပါသည်။ ထို့ကြောင့်၊ သင်သည် PST ဖိုင်တစ်ခုရှိ ဖိုင်တွဲအားလုံး၏ အရွယ်အစား အချက်အလက်ကို အစုလိုက်ရယူလိုပါက အောက်ပါ VBA ကုဒ်ကို အသုံးပြုနိုင်သည်။ ၎င်းသည် ဖိုင်တွဲအမည်များနှင့် အရွယ်အစား အချက်အလက်အားလုံးကို Excel ဖိုင်တစ်ခုသို့ တစ်ကြိမ်တည်း တင်ပို့မည်ဖြစ်သည်။

PST ဖိုင်ရှိ ဖိုင်တွဲအားလုံး၏ အရွယ်အစား အချက်အလက်ကို Excel ဖိုင်တစ်ခုသို့ တင်ပို့ပါ။

1. အစပိုင်းမှာ Outlook application ကိုဖွင့်ပါ။
2. ထို့နောက် “Developer” တက်ဘ်သို့ပြောင်းပြီး “Visual Basic” ခလုတ်ကို နှိပ်ပါ သို့မဟုတ် VBA တည်းဖြတ်မှုကို ဝင်ရောက်ရန် “Alt + F11” ခလုတ်များကို နှိပ်ပါ။
3. ထို့နောက် “Microsoft Visual Basic for Applications” ဝင်းဒိုးတွင်၊ အသုံးမပြုသော မော်ဂျူးတစ်ခုကို ဖွင့်ပါ။
4. ထို့နောက်တွင်၊ အောက်ပါ VBA ကုဒ်များကို ဤ module ထဲသို့ ကူးယူပြီး ကူးထည့်ပါ။

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. ၎င်းနောက်၊ သင်သည်သင်၏ Outlook မက်ခရိုလုံခြုံရေးအဆင့်ကိုနိမ့်ရန်သတ်မှတ်သင့်သည်။
6. နောက်ဆုံးတွင်၊ သင်ကြိုးစားနိုင်သည်။

• လက်ရှိ macro window တွင် F5 ခလုတ်ကို နှိပ်ပါ။
• ထို့နောက် အောက်ပါပုံကဲ့သို့ PST ဖိုင်ကို ရွေးချယ်ရန် သင့်အား တောင်းဆိုပါမည်။
• အရင်းအမြစ်ဖိုင်ကို ရွေးချယ်ပြီးနောက်၊ Outlook သည် အရွယ်အစားအချက်အလက်ကို Excel သို့ စတင်တင်ပို့မည်ဖြစ်သည်။
• မက်ခရို ပြီးပါက၊ အောက်ဖော်ပြပါ ဖန်သားပြင်ဓာတ်ပုံကဲ့သို့ မက်ဆေ့ချ်ကို သင်ရရှိမည်ဖြစ်သည်။
• နောက်ဆုံးအနေဖြင့်၊ သင်သည် ကြိုတင်သတ်မှတ်ထားသော local folder တွင် Excel ဖိုင်ကိုရှာဖွေနိုင်မည်ဖြစ်သည်။ Excel ဖိုင်သည်အောက်ပါပုံအတိုင်းဖြစ်လိမ့်မည်။

မကြာခဏ PST အမှားများကိုဖြေရှင်းပါ။

Outlook သည် အမှားအယွင်းများဖြစ်တတ်သောကြောင့်၊ သင့် Outlook တွင် ပြဿနာများစွာကို သင်ကြုံတွေ့ဖူးပေမည်။ စိတ်ရှုပ်စရာ PST ပြဿနာများကို ပိုမိုကောင်းမွန်ပြီး လိုက်လျောညီထွေစွာ ရင်ဆိုင်ဖြေရှင်းနိုင်ရန်၊ အနီးအနားတွင် အတွေ့အကြုံရှိပြီး ဂုဏ်သိက္ခာရှိသော ပြုပြင်မှု utility ကို ထားရှိရန် အကြံပြုလိုပါသည်။ DataNumen Outlook Repair. တတ်နိုင်သည် PST ကိုပြင်ပါ။ လေညင်းကဲ့သို့ ပြဿနာများ။

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ SQL Server နာလန်ထူ နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com