Outlook Email ၏ ရုပ်ပုံတွဲများကို Excel Worksheet တစ်ခုသို့ အမြန်ထုတ်နည်း

Outlook အီးမေးလ်၏ ရုပ်ပုံ ပူးတွဲပါဖိုင်အားလုံးကို Excel အလုပ်စာရွက်သို့ လျင်မြန်စွာ တင်ပို့လိုပါက၊ ဤဆောင်းပါးကို ကိုးကားနိုင်ပါသည်။ ဤတွင် ကျွန်ုပ်တို့သည် သင့်အား ကိုယ်တိုင်တင်ပို့ခြင်းထက် ပိုမိုထိရောက်သောနည်းလမ်းကို ပြသပါမည်။

Excel မှာ အစီရင်ခံစာရေးသားဖို့အတွက် ပုံတွေ အများကြီးပါတဲ့ အီးမေးလ်တစ်စောင် ရောက်လာတဲ့အခါ ဒီပုံတွေကို Excel worksheet ထဲကို အသုတ်လိုက် export လုပ်နိုင်မယ့် နည်းလမ်းတစ်ခုကို သင် လိုချင်မှာပါ။ အခု အောက်ပါနည်းလမ်းတွေနဲ့ မိတ်ဆက်ပေးပါမယ်။

အီးမေးလ်တစ်ခု၏ ရုပ်ပုံ ပူးတွဲပါဖိုင်အားလုံးကို Excel Worksheet တစ်ခုသို့ ထုတ်ယူပါ။

1. စတင်ရန်၊ သင်၏ Outlook အပလီကေးရှင်းကို ပုံမှန်ပုံစံဖြင့် ဝင်ရောက်ပါ။
2. ထို့နောက် Outlook ဝင်းဒိုးတွင်၊ Alt + F11 ကီးဖြတ်လမ်းများကို နှိပ်ပါ၊ ၎င်းသည် "Microsoft Visual Basic for Applications" ဝင်းဒိုးကို တက်လာစေမည်ဖြစ်သည်။
3. ဤစခရင်တွင်၊ သင်သည် အသုံးမပြုသော module တစ်ခုကိုဖွင့်ရန် သို့မဟုတ် အသစ်တစ်ခုကို တည့်မတ်စွာ ထည့်သွင်းရန် လိုအပ်သည်။
4. ထို့နောက်၊ သင်သည် အောက်ပါ VBA ကုဒ်အပိုင်းအစကို ဤ module ထဲသို့ ကူးယူသင့်သည်။

Sub ExportAllImageAttachmentsToExcelWorksheet()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim strImage As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim objFile As Object
    Dim objFiles As Object
    Dim nRow As Integer
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
 
       'Save the image attachments to a temporary folder
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       'Create a new Excel workbook
        Set objExcelApp = CreateObject("Excel.Application")
        Set objExcelWorkbook = objExcelApp.Workbooks.Add
        Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
        objExcelApp.Visible = True
        objExcelWorkbook.Activate
 
        'Get the images in the temporary folder
        Set objFiles = objFileSystem.GetFolder(strTempFolder).Files
 
        'Insert the images into this new Excel worksheet
        For Each objFile In objFiles
            strImage = strTempFolder & Trim(objFile.Name)
            nRow = nRow + 1
            With objExcelWorksheet
                 .Range("A" & nRow).value = objFile.Name
                 'Change the height and width as per your needs
                 .Range("B" & nRow).ColumnWidth = 10
                 .Range("B" & nRow).RowHeight = 80
                 .Range("B" & nRow).Activate
                 With .Pictures.insert(strImage)
                      With .ShapeRange
                           .LockAspectRatio = msoTrue
                           .Width = 50
                           .Height = 70
                      End With
                 End With
                 .Columns("A").AutoFit
                 .Activate
            End With
       Next
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. ၎င်းနောက်၊ သင်သည် macro မှထွက်နိုင်သည်။
6. ထို့နောက် ဤ macro ကို Quick Access Toolbar သို့ ထည့်ရန် "File" > "Options" > "Quick Access Toolbar" သို့ သွားပါ။
7. နောက်ဆုံးတွင် သင်သည် ဤ macro ကို ယခုပင် စမ်းကြည့်နိုင်ပါသည်။

• ပထမဦးစွာ၊ အရင်းအမြစ်အီးမေးလ်ကိုရွေးချယ်ပါ သို့မဟုတ် ဖွင့်ပါ။
• ထို့နောက် Quick Access Toolbar ရှိ မက်ခရိုခလုတ်ကို နှိပ်ပါ။
• Macro ပြီးသွားသောအခါတွင် အောက်ပါ screenshot ကဲ့သို့ ပြထားသည့် Excel worksheet ကို သင်ရရှိမည်ဖြစ်ပါသည်။

Outlook ဖိုင် ယိုယွင်းလာခြင်းမှ ကာကွယ်ပါ။

Outlook သည် အကျင့်ပျက်ခြစားမှု ဖြစ်နိုင်ကြောင်း လူသိများသည်။ ထို့ကြောင့်၊ Outlook ဖောင်လာဘ်စားမှုကို မည်သို့ကာကွယ်ရမည်ကို ကျွန်ုပ်တို့ နားလည်သင့်သည်။ ပထမဦးစွာ၊ ဗိုင်းရပ်စ်တိုက်ခိုက်မှုများကို ပိတ်ဆို့ရန်အတွက်၊ ဗိုင်းရပ်စ်နှိမ်နင်းရေးဆော့ဖ်ဝဲကို ထည့်သွင်းရန် လိုအပ်ပြီး အမည်မသိ ပူးတွဲပါဖိုင်ကို ဒေါင်းလုဒ်ဆွဲခြင်းမပြုပါနှင့်။ ထို့အပြင်၊ ကျွန်ုပ်တို့ကဲ့သို့သော အစွမ်းထက်သော ပြုပြင်ရေးကိရိယာကို ကိုင်ဆောင်ခြင်းက ပိုကောင်းပါသည်။ DataNumen Outlook Repair။ ၎င်းသည် အောက်ပါအခြေအနေများတွင် အထိရောက်ဆုံး ကုစားနည်းကို ပေးစွမ်းနိုင်သည် အကျင့်ပျက်ခြစားမှုအမြင်.

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ sql ပြန်လည်နာလန်ထူ နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com