များစွာသော Outlook အီးမေးလ်များတွင် ဟိုက်ပါလင့်ခ်များအားလုံးကို Excel သို့ အမြန်တင်ပို့နည်း

အီးမေးလ်တစ်ခု သို့မဟုတ် တစ်ခုထက်ပိုသော အီးမေးလ်များရှိ hyperlink အားလုံးကို ထုတ်ယူရန် လိုအပ်သည့်အခါ ၎င်းတို့ကို တစ်ခုပြီးတစ်ခု ကူးယူခြင်းသည် မိုက်မဲရာကျပါသည်။ ဤပို့စ်သည် အီးမေးလ်များစွာရှိ hyperlink အားလုံးကို Excel သို့ လျင်မြန်စွာ ထုတ်ယူနည်းကို သင်ကြားပေးပါမည်။

သင့်ပေးပို့လိုက်သော အီးမေးလ်များအားလုံးတွင် ဟိုက်ပါလင့်ခ်များကို လော့ဂ်လုပ်ခြင်းကဲ့သို့ အချို့သောအကြောင်းများကြောင့်၊ သင်သည် ဟိုက်ပါလင့်ခ်များကို ထုတ်ယူရန် လိုအပ်မည်ဖြစ်သည်။ သံသယမရှိဘဲ၊ ၎င်းတို့ကို ကိုယ်တိုင်ထုတ်ယူပြီး ကော်ပီကူးရန် အကြံပြုလိုပါသည်။ VBA ကိုအသုံးပြုခြင်းကဲ့သို့သော ပိုမိုထက်မြက်သောချဉ်းကပ်မှုတစ်ခုကို သင် တောင့်တနေရပါမည်။ ဤနေရာတွင် ကျွန်ုပ်တို့သည် သင့်အား လွယ်ကူသောကလစ်ဖြင့် အီးမေးလ်များစွာရှိ ဟိုက်ပါလင့်ခ်များအားလုံးကို Excel သို့တင်ပို့နိုင်သည့် VBA ကုဒ်အပိုင်းအစကို မျှဝေပါမည်။

အီးမေးလ်များစွာရှိ ဟိုက်ပါလင့်ခ်အားလုံးကို Excel သို့ တင်ပို့ပါ။

1. အစပိုင်းမှာ ပုံမှန်အတိုင်း Outlook ပရိုဂရမ်ကို စတင်လိုက်ပါ။
2. ထို့နောက် Outlook ဝင်းဒိုးတွင်၊ သင်သည် "Alt + F11" သော့ခလုတ်များကို နှိပ်ရပါမည်။
3. တစ်ချိန်တည်းတွင် သင်သည် Outlook VBA တည်းဖြတ်သူထံ ဝင်ရောက်ခွင့်ရရှိမည်ဖြစ်သည်။
4. ထို့နောက် “Microsoft Word Object Library” နှင့် “Microsoft Excel Object Library” တို့ကို ဖွင့်ရန် လိုအပ်ပါသည်။ “Tools” > “References” ကို နှိပ်ပြီးနောက် popup dialog box တွင် ၎င်းတို့ကို ဖွင့်ပါ။
5. ထို့နောက်၊ သင်သည် ဤ module ထဲသို့ အောက်ဖော်ပြပါ VBA ကုဒ်ကို ကူးယူရန်အတွက် အသုံးမပြုသော module တစ်ခုကို ဖွင့်ရန်လိုအပ်သည်။

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. ၎င်းနောက်၊ သင်သည် လက်ရှိ VBA တည်းဖြတ်ဝင်းဒိုးမှ ထွက်နိုင်သည်။
7. အသစ်ထည့်ထားသော macro ကို Quick Access Toolbar သို့ထည့်သွင်းရန် Quick Access Toolbar ကို စိတ်ကြိုက်ပြင်ဆင်ရန် နောက်ပိုင်းတွင် “Outlook Options” ကို ဝင်ရောက်ကြည့်ရှုပါ။
8. နောက်ဆုံးတွင် သင်သည် ရိုက်ချက်တစ်ခုကို ရိုက်နိုင်သည်-

• ပထမဦးစွာ၊ အီးမေးလ်စာရင်းတွင်၊ သင်ထုတ်ယူလိုသည့် ဟိုက်ပါလင့်ခ်များကို ရွေးပါ။
• ထို့နောက် Quick Access Toolbar ရှိ မက်ခရိုခလုတ်ကို နှိပ်ပါ။
• Macro ပြီးသောအခါ၊ အောက်ပါပုံကဲ့သို့ Excel ဖိုင်ကို သင်ရရှိမည်ဖြစ်သည်။

မမျှော်လင့်ထားသော Outlook ပြဿနာများကို ဖြေရှင်းပါ။

Outlook ပြဿနာများသည် မည်သည့်နိမိတ်မှမရှိဘဲ တစ်ခါတစ်ရံ ဖြစ်ပွားနိုင်သည်။ သို့သော်၊ အသေးစားအမှားအယွင်းများအရ Outlook သည် ရိုးရှင်းသော restart လုပ်ခြင်း သို့မဟုတ် ၎င်း၏ inbox ပြုပြင်ရေးကိရိယာ. ဒါပေမယ့် ပြင်းထန်တဲ့ ပြဿနာတွေနဲ့ ကြုံလာရရင် အတွင်းနည်းလမ်းက သက်ရောက်မှု ရှိမှာ မဟုတ်ပါဘူး။ ဤအချိန်တွင်၊ သင်၏နောက်ဆုံးအားကိုးရာသည် ပို၍နာမည်ကြီးပြီး ကြံ့ခိုင်သည့်ကိရိယာဖြစ်သည့် သေချာပါသည်။ DataNumen Outlook Repair.

စာရေးသူနိဒါန်း:

Shirley Zhang သည် ဒေတာပြန်လည်ရယူရေးဆိုင်ရာ ကျွမ်းကျင်သူဖြစ်သည်။ DataNumen, Inc. အပါအဝင် ဒေတာပြန်လည်ရယူရေးနည်းပညာများတွင် ကမ္ဘာ့ခေါင်းဆောင်ဖြစ်သည်။ mdf ပျက်စီးနေသည်။ နှင့် outlook ပြုပြင်ရေး software ထုတ်ကုန်များ။ ပိုမိုသိရှိလိုပါကသွားရောက်ကြည့်ရှု www ။datanumen.com