Cara Batch Menghantar Semua Lembaran Kerja dalam Buku Kerja One Excel sebagai E-mel Outlook yang Berasingan

Kongsi Sekarang:

Sekiranya anda ingin mengirim semua lembaran kerja dalam buku kerja Excel sebagai e-mel Outlook yang berasingan, anda boleh menggunakan kaedah yang diperkenalkan dalam artikel ini. Ia dapat membimbing anda untuk menyedarinya secara pukal tanpa menyusahkan menghantarnya satu persatu.

Dalam catatan saya sebelum ini “2 Kaedah Pantas untuk Menghantar Lembaran Kerja Excel sebagai E-mel Outlook", anda boleh mempelajari dua cara untuk menghantar satu lembaran kerja Excel sebagai e-mel. Jika anda ingin menghantar semua lembaran kerja secara berkumpulan dalam satu buku kerja sebagai e-mel individu, menggunakan salah satu daripada dua cara yang dinyatakan dalam catatan itu akan agak membosankan dan menyusahkan. Oleh itu, di sini kami akan memperkenalkan satu lagi cara yang boleh merealisasikan "Hantar Berkelompok" sedemikian dalam masa yang singkat.

Batch Hantar Semua Lembaran Kerja dalam Buku Kerja Satu Excel sebagai E-mel Outlook yang Berasingan

Batch Hantar Semua Lembaran Kerja dalam Buku Kerja Satu Excel sebagai E-mel Berasingan

  1. Pertama, anda harus membuka buku kerja Excel sumber.
  2. Kemudian, setelah memasuki tetingkap Excel, anda harus mengetuk pintasan kekunci "Alt + F11".
  3. Selanjutnya, tetingkap lain yang disebut sebagai "Microsoft Visual Basic for Applications" akan dipaparkan.
  4. Di dalamnya, anda harus membuka modul yang tidak digunakan atau memasukkan modul baru.
  5. Selepas itu, anda boleh menyalin kod VBA berikut ke dalam modul ini.
Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

Kod VBA - Batch Hantar Semua Lembaran Kerja dalam Buku Kerja Satu Excel sebagai E-mel Outlook yang Berasingan

  1. Selepas itu, anda boleh mencetuskan makro ini dengan menekan butang F5 atau mengklik ikon "Jalankan" di bar alat.
  2. Sekaligus, e-mel, yang sesuai dengan semua lembaran kerja dalam buku kerja Excel ini, akan dipaparkan di Outlook.
  3. Akhirnya, anda boleh memeriksa semula semua butiran e-mel dan terakhir klik butang "Kirim" untuk menghantar e-mel tersebut.

Sapukan Alat Pemulihan Berpotensi jika Tiada Sandaran

Semakin banyak pengguna telah memahami pentingnya sandaran data. Selagi anda membuat sandaran fail PST anda, Pemulihan PST selepas kerosakan akan menjadi sederhana. Tetapi jika tidak ada sandaran PST yang berkesan dan terkini, anda tidak mempunyai pilihan selain mengambil bantuan alat pembaikan PST luaran, seperti DataNumen Outlook Repair. Ia dapat memperbaiki fail PST yang dikompromikan seperti angin.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pulihkan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com

Kongsi Sekarang:

Ruangan komen telah ditutup.