Cara Auto Menggunakan Pencetak Khusus untuk Mencetak Email Outlook

Anda tidak dapat mengkonfigurasi Outlook untuk menggunakan pencetak bukan lalai tertentu untuk mencetak e-mel. Tetapi dalam artikel ini, kami akan menunjukkan kaedah untuk mencapainya dengan Outlook VBA.

Komputer anda mesti menetapkan pencetak sebagai lalai, yang akan digunakan untuk semua program di komputer ini. Dalam kes ini, jika anda ingin mencetak e-mel melalui pencetak bukan lalai di Outlook, anda harus menukar pencetak setiap kali semasa mencetak. Ia cukup menyusahkan. Oleh itu, berikut ini, kami akan berkongsi cara untuk menggunakan pencetak khusus untuk e-mel secara automatik tanpa perlu menukar pencetak setiap kali.

Gunakan Pencetak Khusus untuk Mencetak E-mel secara automatik

1. Pada mulanya, mulakan aplikasi Outlook anda.
2. Kemudian, di tetingkap Outlook utama, tekan butang kekunci "Alt + F11".
3. Seterusnya, dalam tetingkap “Microsoft Visual Basic for Applications” yang dipaparkan, anda perlu mendayakan “Microsoft Word object Library” terlebih dahulu. Anda boleh mengklik 'Tools” > “Reference” untuk melakukannya.
4. Kemudian, anda perlu mengakses modul kosong.
5. Selepas itu, salin dan tampal kod VBA berikut ke dalam modul ini.

Sub PrintEmail()
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objWordApp As Word.Application
    Dim strTempFolder As String
    Dim strMailDocument As String
    Dim objMailDocument As Word.Document
    Dim strPrinter As String

    Select Case Application.ActiveWindow.Class
           Case olInspector
                Set objItem = ActiveInspector.CurrentItem
           Case olExplorer
                Set objItem = ActiveExplorer.Selection.Item(1)
    End Select
 
    If TypeOf objItem Is MailItem Then
       Set objMail = objItem
 
       Set objWordApp = CreateObject("Word.Application")
       strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
       strMailDocument = strTempFolder & "\" & Format(Now, "yyyymmddssnn") & ".doc"
       objMail.SaveAs strMailDocument, olDoc
 
       Set objMailDocument = objWordApp.Documents.Open(strMailDocument)
       objWordApp.Visible = True
       objMailDocument.Activate
 
       strPrinter = objWordApp.ActivePrinter
       'Change to the name of specific printer
       objWordApp.ActivePrinter = "Specific Printer"
       objWordApp.PrintOut Range:=wdPrintAllDocument, Item:=wdPrintDocumentContent
       objWordApp.ActivePrinter = strPrinter
 
       objMailDocument.Close False
       objWordApp.Quit
       Kill strMailDocument
    End If
End Sub

6. Selepas itu, anda boleh menutup tetingkap semasa.
7. Kemudian, pergi ke menu "Fail" dan klik "Pilihan".
8. Di tetingkap "Opsi Outlook", beralih ke tab "Bar Alat Akses Pantas" dan tambahkan makro baru ke Bar Alat Akses Pantas seperti biasa.
9. Akhirnya, anda boleh mencuba projek VBA ini.

• Pertama, pilih atau buka e-mel yang ingin anda cetak.
• Kemudian, klik pada butang makro di Bar Alat Akses Pantas.
• E-mel akan dicetak oleh pencetak tertentu sekaligus.

10. Mulai sekarang, untuk mencetak e-mel oleh pencetak tertentu, anda boleh menggunakan makro ini.

Pulihkan Outlook selepas Rasuah Kemalangan

Untuk menghalang data Outlook anda daripada hilang, anda perlu berusaha keras. Contohnya, anda harus membuat sandaran fail PST anda secara berkala. Sudah tentu, adalah disyorkan untuk mendapatkan alat pembaikan luaran, seperti DataNumen Outlook Repair. Ia boleh betulkan PST ralat dan pulihkan data Outlook maksimum untuk anda.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pulihkan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com