Cara Batch Menghapus Lampiran dari Item Kalendar Yang Tertinggal di Outlook Anda

Sekiranya anda ingin membuang lampiran dari janji temu dan mesyuarat yang ketinggalan zaman di Outlook, anda boleh membaca artikel ini. Di sini kami akan memperkenalkan anda bagaimana mewujudkannya dalam satu masa.

Untuk mengurangkan saiz fail Outlook anda, sangat disarankan untuk membersihkan item lama. Ini dapat direalisasikan dengan fitur "AutoArchive" yang sudah ada, yang dapat menghapus item lama secara automatik secara berkala. Walau bagaimanapun, sebilangan pengguna hanya mahu menghapus lampiran pada item lama tanpa mempengaruhi item itu sendiri. Berikut ini, kami akan mengajar anda untuk membuang lampiran secara pukal dari item kalendar lama.

Batch Buang Lampiran dari Item Kalendar Yang Tertinggal

1. Sebagai permulaan, akses editor Outlook VBA dengan "Alt + F11".
2. Kemudian, di tetingkap "Microsoft Visual Basic for Applications", salin kod VBA ke dalam modul.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Selepas itu, klik dalam makro "BatchDeleteAttachmentsOfOldCalendarItems".
4. Akhirnya, tekan butang "F5" untuk menjalankan makro ini.
5. Apabila makro selesai, anda dapat memeriksa semua kalendar Outlook anda.
6. Outlook mesti telah menghapus semua lampiran item kalendar yang berumur lebih dari 2 bulan.

Mengatasi fail Outlook yang rosak

Adakah anda pernah mengalami kerosakan Outlook? Bagaimana anda membuangnya biasanya? Lebih kerap daripada anda, anda akan terlebih dahulu mencuba alat pembaikan peti masuk - scanpst. Tetapi, sekiranya berlaku kerosakan PST yang serius, utiliti terpasang tidak dapat membantu anda. Oleh itu, disarankan untuk menyimpan alat pihak ketiga yang lebih berpengalaman dan luar biasa di sekitarnya, seperti DataNumen Outlook Repair.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pembaikan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com