Cara Batch Eksport Beberapa E-mel Outlook ke dalam Dokumen One Word melalui VBA

Sekiranya anda ingin mengeksport banyak e-mel Outlook ke dalam dokumen satu perkataan, anda boleh menggunakan kod VBA yang ditunjukkan dalam artikel ini. Ini dapat membantu anda menyelesaikan tugas ini dalam beberapa saat.

Saya pernah memperkenalkan cara menukar e-mel Outlook menjadi dokumen Word dalam artikel saya sebelumnya - “2 Kaedah Berkesan untuk Menukar E-mel Outlook ke dokumen Word" Walau bagaimanapun, kedua-dua cara yang disebutkan dalam hal ituost tidak berdaya sekiranya anda ingin mengeksport banyak e-mel ke dalam satu dokumen Word. Oleh itu, di sini kami akan mengajar anda dengan cara lain. Sekarang, baca untuk mendapatkannya dengan terperinci.

Batch Export Multiple Outlook Email ke dalam One Word Document

1. Kepada start, lancarkan program Outlook anda.
2. Kemudian, setelah memasuki tetingkap Outlook utama, anda perlu menekan butang "Alt + F11".
3. Seterusnya anda akan mendapat akses ke editor Outlook VBA, di mana anda harus membuka modul kosong.
4. Selepas itu, salin kod VBA di bawah ke tetingkap modul yang dibuka.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Selepas itu, lebih baik anda menambah projek VBA baru ini ke Papan Alat Akses Pantas atau pita.
6. Pada akhirnya, anda boleh mencuba.

• Pertama, pilih banyak e-mel Outlook.
• Kemudian cari dan klik pada butang makro yang baru ditambahkan.
• Setelah diminta "Selesai", anda boleh melihat ke folder tempatan yang telah ditentukan untuk mencari dokumen Word baru.
• Buka dokumen ini, di mana anda dapat melihat semua e-mel yang dipilih telah dieksport.

Pastikan Alat Pemulihan Perkasa Berdekatan

Terlepas dari banyak fungsi, Outlook tetap tidak dapat kebal dari kesalahan. Sekiranya anda terbiasa membiarkan kesilapan sahaja, dengan kesalahan yang semakin meningkat, keruntuhan Outlook akan berlaku dengan pasti. Pada ketika itu, adalah mustahak untuk menggunakan alat pemulihan yang hebat dan berkesan, seperti DataNumen Outlook Repair. Ia berpengalaman luas Pembaikan PST. Selagi dengannya, anda tidak perlu lagi risau akan kehilangan data prospek.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rosak dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com