Cara Cepat Mengeksport Statistik Pengundian dari E-mel Outlook ke Lembaran Kerja Excel

Sekiranya anda telah menghantar e-mel dengan butang suara, setelah penerima menghantar balasan kepada anda, anda mungkin ingin mengira dan mengeksport statistik pengundian ke lembaran kerja Excel. Jadi, dalam hlm iniost, kami akan mengajar anda bagaimana mencapainya dengan cepat.

Outlook sangat hebat sehingga bahkan menawarkan ciri "Mengundi". Artikel saya sebelum ini “Penggunaan MS Outlook untuk Mengundi dengan mahir"Telah mengajar bagaimana menggunakannya dengan berkesan. Juga, most pada waktunya, setelah mengundi, anda boleh terus mengeksport statistik pengundian ke lembaran kerja Excel untuk beberapa sebab, seperti ingin mencetak statistik. Tetapi Outlook tidak menyokong ini secara lalai. Oleh itu, berikut ini, kami akan mengajar anda bagaimana mewujudkannya seperti gabus.

Eksport Statistik Pengundian dalam E-mel ke Lembaran Kerja Excel

1. Pada awalnya, lancarkan aplikasi Outlook anda.
2. Kemudian anda harus menekan butang "Alt + F11" di tetingkap utama Outlook.
3. Selanjutnya di tetingkap "Microsoft Visual Basic for Applications", anda harus mengaktifkan "Microsoft Excel Object Library ”. Klik "Alat"> "Rujukan". Kemudian di kotak dialog timbul, tandai kotak centang di hadapan "Microsoft Excel Object Library "dan tekan" OK "terakhir.
4. Selepas itu, anda boleh memasukkan modul baru atau membuka modul yang tidak digunakan.
5. Selepas itu, salin dan tampal kod VBA berikut ke dalam modul ini.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Selepas itu, untuk akses yang mudah, anda lebih baik menambahkan makro baru ke Quick Access Toolbar.
6. Akhirnya, anda boleh mencuba.

• Pertama, pilih e-mel sumber yang mengandungi butang mengundi.
• Kemudian klik butang makro di Bar Alat Akses Pantas.
• Setelah makro ini selesai dijalankan, anda boleh melihat ke folder tempatan yang telah ditentukan, di mana anda akan melihat buku kerja Excel yang baru.
• Buka buku kerja Excel ini. Sekarang anda akan melihat statistik pengundian, seperti gambar di bawah:

Tidak ada yang dapat mengelakkan ralat Outlook dengan teliti

Walaupun Outlook dikurniakan dengan pelbagai kemampuan, tidak ada fitur seperti itu untuk membantu kita menghindari kesalahan Outlook. Semua jenis faktor boleh menyebabkan kesalahan Outlook. Contohnya, jika anda sering keluar dari Outlook dengan tidak betul, anda mungkin akan menderita Rasuah PST. Dalam senario seperti itu, anda tidak mempunyai pilihan selain menggunakan beberapa alat yang kuat untuk menyelamatkan fail PST anda, seperti DataNumen Outlook Repair. Ia mendapat banyak pujian kerana kadar pemulihannya yang tinggi.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rosak dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com