Cara Auto Mengalihkan E-mel dengan Penerima CC Tertentu dalam Outlook

Pada hakikatnya, kebanyakan daripada anda mungkin berharap untuk mencipta peraturan Outlook untuk memindahkan e-mel secara automatik dengan penerima CC tertentu. Tetapi peraturan Outlook tidak menyokong semakan penerima CC. Jadi artikel ini akan mengajar anda cara merealisasikannya dengan Outlook VBA.

Jelas sekali, adalah mustahil untuk anda membuat peraturan Outlook untuk mencari penerima CC tertentu. Seperti yang ditunjukkan dalam tangkapan skrin berikut, untuk e-mel yang diterima, anda hanya boleh menyemak sama ada nama anda sendiri ada dalam kotak CC. Begitu juga, untuk e-mel yang dihantar, walaupun tiada syarat peraturan untuk menyemak kotak CC.

Oleh itu, jika anda ingin mengkonfigurasi Outlook untuk memindahkan e-mel dengan penerima CC tertentu secara automatik, anda perlu mencari cara lain. Kemudian. di sini kami akan mengajar anda cara untuk mencapainya melalui Outlook VBA.

Auto Alihkan E-mel Dihantar dengan Penerima CC Tertentu

1. Mula-mula, beralih ke tab "Pembangun" dan klik pada butang "Visual Basic".
2. Kemudian buka projek "ThisOutlookSession" dan salin kod VBA berikut ke dalamnya.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. Selepas itu, anda harus terus menandatangani kod ini dan menukar tetapan makro seperti biasa.
4. Akhir sekali, anda boleh keluar dari tetingkap "Visual Basic". Selepas itu, e-mel dengan penerima CC tertentu akan dialihkan ke folder mel yang ditentukan.

Alihkan Auto E-mel yang Diterima dengan Penerima CC Tertentu

Memandangkan kod VBA di atas bertujuan untuk memindahkan e-mel yang dihantar dengan penerima CC tertentu, Jika anda ingin mencari penerima CC tertentu dalam e-mel yang diterima dan kemudian mengalihkannya, anda harus menggunakan kod berikut.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Sentiasa Bersedia untuk Kerosakan Outlook

Walaupun Outlook kaya dengan ciri, ia masih tidak boleh kebal daripada rasuah. Oleh itu, anda harus sentiasa berwaspada terhadap semua kemungkinan risiko. Tidak dinafikan, langkah kritikal mestilah membuat sandaran yang konsisten dan terkini untuk data Outlook. Tambahan pula, anda harus menyimpan a alat pemulihan Outlook yang rosak di kawasan berhampiran. Ia akan berguna jika kedua-dua sandaran dan Scanpst.exe gagal.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pembaikan SQL Server ralat fail mdf dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com