6 Cara untuk Menyimpan Lampiran E-mel Asal semasa Membalas dalam Outlook

Ramai pengguna berharap untuk mengkonfigurasi Outlook mereka untuk menyimpan lampiran e-mel asal semasa membalas e-mel. Artikel ini akan mendedahkan 5 penyelesaian serta cara pintar, iaitu menggunakan VBA untuk merealisasikannya secara automatik.

Saya telah mendengar sebilangan besar pengguna mengadu bahawa Outlook tidak mempunyai ciri asli untuk menyimpan lampiran asal semasa membalas e-mel. Oleh itu, di sini kami akan berkongsi kepada anda 6 kaedah, salah satunya adalah sangat berguna kerana ia menggunakan VBA untuk membuat Outlook melampirkan lampiran asal secara automatik untuk membalas e-mel. Sekarang baca terus untuk mendapatkannya secara terperinci.

1. Balas dengan E-mel Asal Dilampirkan

Walaupun Outlook tidak menyediakan ciri untuk menyimpan lampiran e-mel asal semasa membalas e-mel, ia membenarkan pengguna menyimpan e-mel asal dilampirkan. Oleh itu, ia adalah penyelesaian pilihan untuk anda. Anda boleh pergi ke bahagian "Fail" > "Pilihan" > "Mel" > "Balasan dan ke hadapan" untuk menukar tetapan balasan. Untuk butiran lanjut, dicadangkan anda merujuk artikel saya sebelum ini – “5 Langkah Membalas dengan Lampiran Asal di Outlook”. Tetapi, jika anda masih berharap untuk menyimpan lampiran asal sahaja, teruskan untuk mempelajari cara lain.

2. Seret & Lepaskan Lampiran Secara Manual

1. Untuk bermula, klik dua kali e-mel sumber tersebut untuk membukanya dalam tetingkapnya sendiri.
2. Kemudian klik butang "Balas", yang akan memaparkan e-mel membalas.
3. Seterusnya anda harus mengecilkan kedua-dua tetingkap Mesej sehingga anda dapat melihatnya dalam skrin yang sama.
4. Selepas itu, pilih semua lampiran dalam e-mel asal.
5. Akhir sekali, seret dan lepaskan mereka ke baris "Dilampirkan" dalam e-mel membalas.

3. Salin & Tampal Lampiran Secara Manual

1. Di tempat pertama, selepas membuka e-mel sumber, pilih semua lampiran.
2. Kemudian klik butang "Salin" di bawah tab "Lampiran".
3. Selepas itu, klik butang "Balas" di bawah tab "Mesej" untuk membuka mel membalas.
4. Akhirnya, dalam e-mel yang membalas, klik pada baris "Dilampirkan" dan tekan butang "Ctrl + V" untuk menampal lampiran yang disalin sebelum ini.

4. Majukan E-mel & Isi Penerima

1. Mula-mula, pilih e-mel sedemikian dan kemudian klik butang "Majukan" dalam reben.
2. Dalam tetingkap Mesej yang baru timbul, lampiran asal disimpan. Sekarang anda perlu mengisi medan "Kepada" kepada pengirim e-mel asal.
3. Secara pilihan, anda boleh menukar subjek mengikut keperluan anda.

5. Hantar Semula E-mel Ini & Tukar Penerima

1. Untuk memulakan, buka e-mel sumber.
2. Kemudian klik butang "Tindakan" dalam kumpulan "Pindah".
3. Seterusnya pilih "Hantar Semula Mesej Ini" daripada senarai juntai bawah.
4. Mungkin anda akan mendapat makluman yang menyatakan bahawa anda bukan pengirim asal. Abaikan sahaja dan tekan "Ya".
5. Dalam e-mel baharu yang berikutnya, anda harus mengubah suai medan "Kepada" kepada pengirim e-mel asal.
6. Juga, ingat untuk menukar akaun hantar menggunakan e-mel kepada akaun anda sendiri.

6. Auto Tambah Lampiran Asal melalui VBA

Semua pendekatan yang disebutkan di atas, sejujurnya, adalah penyelesaian. Jika anda berharap Outlook boleh menyimpan lampiran asal secara automatik semasa membalas, anda boleh menggunakan cara ini.

1. Dalam tetingkap Outlook utama, tekan kekunci "Alt + F11".
2. Kemudian, di tetingkap "Microsoft Visual Basic for Applications", salin kod VBA di bawah ke dalam projek "ThisOutlookSession".

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

3. Kemudian tandatangani makro ini dan tukar tetapan makro Outlook anda untuk membenarkan makro yang ditandatangani.
4. Selepas itu, mulakan semula aplikasi Outlook anda untuk mengaktifkan projek VBA ini.
5. Mulai sekarang, setiap kali anda mengklik butang "Balas". E-mel yang membalas akan dipaparkan dengan lampiran asal sekaligus.

Pilih Alat Pembaikan Terunggul

Outlook telah memikul pelanggan e-mel lain kerana pelbagai cirinya. Tetapi ia masih terdedah kepada rasuah. Oleh itu, anda harus memberi lebih perhatian kepada kesihatannya. Secara umum, apabila menghadapi masalah kecil, anda hanya boleh mengulangi utiliti pembaikan terbina dalam. Namun begitu, jika anda mengalami masalah yang serius, anda lebih baik menggunakan alat yang lebih mahir, seperti DataNumen Outlook Repair. Ia boleh betulkan Outlook fail dalam sekejap.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memperbaiki sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com