Cara Mengeksport Struktur Folder Fail Outlook Anda ke Excel

Sekiranya anda ingin dengan cepat mengeksport struktur folder fail data Outlook anda ke buku kerja Excel, anda boleh menggunakan kaedah yang diperkenalkan dalam artikel ini.

Untuk beberapa sebab, seperti mencatatkan folder dan subfolder Outlook semasa, banyak pengguna berharap dapat mengeksport struktur folder fail Outlook ke fail luaran, seperti buku kerja Excel. Berikut ini, kami akan berkongsi sekeping kod VBA, yang dapat membantu anda mencapainya dengan cepat.

Eksport Struktur Folder Fail Outlook Anda ke Excel

1. Kepada start, lancarkan aplikasi Outlook anda.
2. Kemudian, di tetingkap Outlook utama, tekan butang kekunci "Alt + F11".
3. Seterusnya, anda akan memasuki editor Outlook VBA, di mana anda harus membuka modul yang tidak digunakan.
4. Selepas itu, anda boleh menyalin kod VBA berikut ke dalam modul ini.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

5. Selepas itu, anda harus memastikan bahawa Outlook telah mengaktifkan makro.
6. Akhirnya, anda boleh mengambil gambar:

• Di tetingkap makro semasa, tekan butang kekunci F5.
• Setelah makro selesai, anda akan mendapat amaran yang meminta "Selesai".
• Kemudian, anda boleh menuju ke folder tempatan yang telah ditentukan untuk mencari fail Excel baru. Buka dan akan kelihatan seperti tangkapan skrin berikut:

Jangan Mengabaikan Kesalahan Outlook

Walaupun dengan kemampuan yang banyak, Outlook juga rentan terhadap kesalahan dan kerosakan seperti klien e-mel lain. Oleh itu, anda harus mementingkan semua kesalahan dalam Outlook anda. Jangan abaikan mereka. Jika tidak, kesilapan terkumpul boleh menyebabkan kerosakan Outlook akhirnya. Jika berhadapan dengan kesalahan yang diinginkan, disarankan untuk menggunakan alat yang kuat, seperti DataNumen Outlook Repair, yang boleh baiki Outlook kesilapan dalam beberapa saat.

Pengenalan Pengarang:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk pemulihan sql dan produk perisian pembaikan prospek. Untuk maklumat lebih lanjut, lawati www.datanumen.com