3 Kaedah Makro Menukar Dokumen Word Anda dengan Cepat PDF Fail

Dalam artikel ini, kami akan memberi tumpuan kepada menyediakan 3 makro yang boleh anda gunakan untuk menukar dokumen Word menjadi cepat pdf fail.

Di Word 2003, terdapat ikon pada bar menu. Dengan satu klik, pengguna dapat mencetuskan tetingkap "Simpan Sebagai" dengan serta-merta dan menyimpan dokumen tersebut pdf format.

Namun, seperti yang anda perhatikan, susun atur di Word 2010 banyak berubah. Dan pengguna harus mengklik tab "File" kemudian perintah "Save As" untuk memicu tetingkap "Save As". Selain itu, anda harus memilih jenis simpan secara manual sebelum menekan butang "Simpan".

Dengan semua klik ini, ia tidak cukup pantas. Oleh itu, dalam catatan ini, kami ingin menunjukkan cara makro untuk melakukannya.

Makro 1: Cetuskan Tetingkap "Simpan Sebagai" Dengan Cepat

1. Pertama sekali, klik tab “Pembangun” kemudian klik arahan “Visual Basic” untuk membuka editor VBA. Sudah tentu, 2 klik perlu dilakukan apabila tab “Pembangun” telah dipaparkan. Cara alternatifnya ialah dengan menekan “Alt+ F11”.
2. Kedua, klik projek "Normal".
3. Ketiga, klik "Insert" dan kemudian pilih "Module" pada menu senarai.
4. Sekarang klik dua kali pada modul untuk menunjukkan kawasan penyuntingan.
5. Seterusnya, tampal kod berikut:

Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub

6. Kemudian klik "Jalankan".

Sekarang terdapat tetingkap "Simpan Sebagai". Dan jenis simpan sudah dalam bentuk pdf. Apa yang tinggal hanyalah klik pada butang "Simpan". Makro ini membolehkan anda menukar nama fail jika perlu.

Makro 2: Simpan Fail Word Secara Langsung ke PDF

Sekiranya ada orang mahu menyimpan fail tersebut terus ke pdf tanpa menyemak semula nama fail, berikut adalah makro yang diperlukan.

1. Pertama sekali, ulangi 4 langkah pertama di atas.
2. Seterusnya, tampal kod berikut:

'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub

3. Begitu juga, klik "Run".

Makro 3: Tukar Fail Word Docx kepada PDF secara Berkelompok

1. Letakkan semua fail docx dalam satu folder terlebih dahulu.
2. Ikuti langkah-langkah di atas untuk membuka kawasan penyuntingan.
3. Kemudian tampal makro berikut:

Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. Jangan lupa untuk mengklik butang "Jalankan".

Nota: Dalam kod "strFolder = "C: \ Users \ Test \ Desktop \ Test Files \"",""C: \ Users \ Test \ Desktop \ Test Files \" " adalah laluan fail folder. Ingatlah untuk mengubahnya dengan sewajarnya.

Selepas menjalankan makro ini, PDF akan disimpan dalam folder yang sama di mana dokumen Word berada.

Fail Selamat Seboleh-bolehnya

Terdapat langkah pencegahan dan juga tindakan pasca bencana untuk menyelamatkan fail yang rosak. Jika anda terus membuat sandaran fail anda secara berkala, mendapatkan kembali fail asal hanyalah sesuatu yang mudah. ​​Sebenarnya, hanya segelintir orang yang boleh mematuhi pelan sandaran mereka, justeru meningkatkan risiko kehilangan data berharga. Dalam keadaan sedemikian, sudah tiba masanya untuk menggunakan kaedah lanjutan. Alat pembetulan rasuah dokumen perkataan.

Pengenalan Pengarang:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk kerosakan Excel xlsx rosak dan pdf membaiki produk perisian. Untuk maklumat lebih lanjut, lawati www.datanumen.com