Kā ātri izdrukāt visus Outlook e-pasta attēlu pielikumus tikai vienā lapā

Lai taupītu printera tinti un papīru, daži lietotāji vēlas izdrukāt visus e-pasta ziņojumam pievienotos attēlus tikai uz vienas lapas, nevis vienu attēlu katrā lapā. Tagad šajā rakstā tiks aprakstīti līdzekļi, kā to realizēt.

Kā mēs visi zinām, attēlu drukāšana ir diezgan tērēta printera tinte. Tādējādi, lai taupītu printera tinti un papīru, iespējams, dodat priekšroku daudzu attēlu pielikumu drukāšanai uz vienas lapas, nevis attēlu drukāšanai uz atsevišķām lapām. Lai gan Outlook nepiedāvā šādu līdzekli, jūs joprojām varat to sasniegt, izmantojot tālāk norādītos līdzekļus.

Drukājiet visus Outlook e-pasta attēlu pielikumus tikai vienā lapā

1. Lai sāktu, palaidiet savu Outlook lietojumprogrammu.
2. Pēc tam Outlook logā pieskarieties pogām Alt + F11.
3. Pēc tam jūs nokļūsiet logā “Microsoft Visual Basic for Applications”, kurā vispirms ir jāiespējo “Microsoft Word objektu bibliotēka”.
4. Pēc tam jums ir jāatver modulis, kas netiek izmantots.
5. Pēc tam šajā modulī nokopējiet un ielīmējiet šādu VBA kodu.

Sub PrintAllImageAttachmentsOnOnePage()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objTempMail As Outlook.MailItem
    Dim objTempDocument As Word.Document
    Dim objWordApp As Word.Application
    Dim strImage As String
    Dim objImage As Word.InlineShape
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objSourceMail = ActiveInspector.currentItem
           Case olExplorer
                Set objSourceMail = ActiveExplorer.Selection.Item(1)
    End Select
 
    If Not (objSourceMail Is Nothing) Then
       'Create a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       Set objTempDocument = objTempMail.GetInspector.WordEditor
       Set objWordApp = objTempDocument.Application
 
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.attachments
           'Get the Image attachments, instead of inserted Images
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                          strImage = "E:\" & objAttachment.filename
                          objAttachment.SaveAsFile strImage
 
                          'Insert the images into the temp mail
                          Set objImage = objWordApp.Selection.InlineShapes.AddPicture(filename:=strImage, LinkToFile:=False, SaveWithDocument:=True)
                          objWordApp.Selection.TypeText Text:=" "
 
                          'shrink the images to insure that they are on one page
                          objImage.ScaleHeight = 20
                          objImage.ScaleWidth = 20
 
                          Kill strImage
             End Select
           End If
       Next
 
       objTempMail.PrintOut
       objTempMail.Close olDiscard
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

6. Vēlāk varat atgriezties e-pasta sarakstā. Izvēlieties vai atveriet e-pasta ziņojumu, kura attēlu pielikumus vēlaties izdrukāt.
7. Pēc tam aktivizējiet šo makro. Pašreizējā makro logā vienkārši nospiediet taustiņu "F5" vai noklikšķiniet uz ikonas "Palaist" rīkjoslā.
8. Visbeidzot, kad makro ir pabeigta, visi avota e-pasta attēlu pielikumi tiks izdrukāti vienā lapā, piemēram, šajā ekrānuzņēmumā:

Darbs ar bojātiem Outlook failiem

Tā kā programmā Outlook tiek glabāts arvien vairāk datu, jūsu Outlook fails kļūst arvien neaizsargātāks. Tas var tikt apdraudēts dažādu iekšēju un ārēju faktoru dēļ. Turklāt ir grūti paredzēt Outlook korupciju. Tātad, ko jūs varat darīt, ir nodrošināt tūlītēju un efektīvu glābšanu, saskaroties ar Outlook bojājumiem. Piemēram, jums ir jāsaglabā specializācija PST remonts rīks, piemēram DataNumen Outlook Repair tuvumā. Tas skenēs un atjaunos bojātos failus kā brīze.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp atgūt Sql Server un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar