Kā ātri atrast viena teikuma rindkopas Word dokumentā

Šajā ierakstā mēs vēlamies parādīt jums ātru veidu, kā, izmantojot VBA, atrast visas viena teikuma rindkopas savā Word dokumentā.

Šad tad dažiem dokumentiem var būt ļoti specifiskas prasības to formatēšanai un struktūrai. Piemēram, jums var nebūt atļauts izmantot rindkopas ar tikai vienu teikumu. Šīs rindkopas nav grūti atpazīt, taču tas prasa laiku, it īpaši tas ir garš dokuments.

Šodien mēs piedāvāsim jums ātru veidu, kā dokumentā norādīt visas viena teikuma rindkopas.

Atrodiet visus viena teikuma punktus vienā dokumentā

1. Pirmkārt, Word punktu skaita kā teikumu. Tātad, ja ir tādi vārdi kā “kungs” vai “Ms.”, Word to uzskata par teikumu. Lai izslēgtu šādu uzmanību, jums jāaizstāj “Mr.” ar “Mr”. Kad esat pabeidzis atrast viena teikuma rindkopu, varat tos mainīt atpakaļ. Lai aizstātu vārdus, varat atsaukties uz šo saiti: Kā atrast un aizstāt vairākus vienumus savā Word dokumentā
2. Otrkārt, nospiediet “Alt + F11”, lai aktivizētu VBA redaktoru.
3. Pēc tam noklikšķiniet uz “Normal” projekta.
4. Izvēlņu joslā noklikšķiniet uz cilnes “Ievietot” un tās nolaižamajā izvēlnē izvēlieties “Modulis”.
5. Nākamais veiciet dubultklikšķi uz moduļa, lai to atvērtu.
6. Modulī ielīmējiet šādus kodus:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Visbeidzot, bet ne mazāk svarīgi, noklikšķiniet uz pogas “Palaist” vai nospiediet “F5”.

Jūs saņemsit šādu ziņojumu lodziņu, kurā būs norādīts, ka darbs ir pabeigts.

Atrodiet visus viena teikuma punktus vairākos dokumentos

1. Vispirms visi mērķa dokumenti jāievieto mapē.
2. Pēc tam instalējiet un palaidiet makro:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. Atvērtajā logā “Pārlūkot” izvēlieties mapi, kurā glabājat dokumentus, un noklikšķiniet uz “Labi”.

Pēc tam makro izceļ visas viena teikuma rindkopas un dokumentus atstāj atvērtus. Ja dokumentā nav viena teikuma rindkopas, tas tiks aizvērts. Turklāt katrā ziņojumā ir ziņojumu lodziņš, kurā norādīts viena teikuma rindkopu skaits.

Nodarbojieties ar datu zaudēšanas gadījumu

Lietotāju kļūdas un pēkšņa strāvas padeves pārtraukšana var izraisīt Word darbību. Kaut arī sabrukušais vārds var ne tikai ietekmēt ikdienas darbu, bet arī novest pie tā doc bojājumiŠī nebūt nav viskaitinošākā datu katastrofas daļa. Labāk ir iegūt atjaunošanas utilītu, lai nekavējoties atgūtu datus.

Autora ievads:

Vera Čena ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp atgūt excel un pdf programmatūras produktu labošana. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar