Kā ātri iegūt pielikumus no visiem Outlook mapē esošajiem Outlook ziņojumu failiem

Varbūt esat saglabājis vairākus Outlook e-pastus .msg formātā Windows mapē. Un vēlāk jūs vēlaties iegūt pielikumus no šiem failiem, varat izmantot šajā rakstā kopīgoto veidu.

Ir diezgan viegli iegūt pielikumus no jūsu Outlook e-pastiem. Bet kā ar e-pastiem, kas eksportēti kā .msg faili Windows mapē? Vispirms jums vispirms jāatver šie .msg faili programmā Outlook un pēc tam atsevišķi jāsaglabā no tiem pielikumi. Varbūt jūs to izjutīsit pārāk apgrūtinoši. Tātad tālāk mēs jums iemācīsim vēl vienu daudz ātrāku risinājumu.

Izvilkt pielikumus no visiem Outlook mapē esošajiem Outlook ziņojumu failiem

1. Lai sāktu, palaidiet savu Outlook lietojumprogrammu un palaidiet VBA redaktoru.
2. Pēc tam logā “Microsoft Visual Basic for Applications” nokopējiet zemāk esošo VBA kodu neizmantotā modulī.

Dim strAttachmentFolder As String

Sub ExtractAttachmentsFromEmailsStoredinWindowsFolder()
    Dim objShell, objWindowsFolder As Object
 
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       'Create a new folder for saving extracted attachments
       strAttachmentFolder = "E:\Attachments-" & Format(Now, "MMDDHHMMSS") & "\"
       MkDir (strAttachmentFolder)
       Call ProcessFolders(objWindowsFolder.self.Path & "\")
       MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFiles As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim i As Long
    Dim objSubFolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
    Set objFiles = objFolder.Files
 
    For Each objFile In objFiles
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           'Open the Outlook emails stored in Windows folder
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              If objItem.Attachments.Count > 0 Then
                 'Extract attachments
                 For i = objItem.Attachments.Count To 1 Step -1
                     objItem.Attachments(i).SaveAsFile strAttachmentFolder & objItem.Attachments(i).FileName
                 Next
              End If
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubFolder In objFolder.SubFolders
           If ((objSubFolder.Attributes And 2) = 0) And ((objSubFolder.Attributes And 4) = 0) Then
              Call ProcessFolders(objSubFolder.Path)
           End If
       Next
    End If
End Sub

3. Pēc tam pārvietojiet kursoru pirmajā apakšprogrammā un nospiediet taustiņa “F5” taustiņu.
4. Pēc tam uznirstošajā dialoglodziņā jums būs jāizvēlas avota Windows mape.
5. Pēc noklikšķināšanas uz Labi, makro turpinās darboties.
6. Kad tas būs pabeigts, jūs saņemsit ziņojumu “Pabeigts”.
7. Tagad jūs varat piekļūt iepriekš noteiktai vietējai mapei, lai saglabātu izvilktos pielikumus.

Efektīvi nokārtot Outlook problēmas

Tā kā programma Outlook, protams, ir pakļauta kļūdām, jums jāuztur piesardzīgi, rīkojoties ar Outlook objektiem, piemēram, nekad neuzticēties nezināmos e-pastos iegultiem failiem vai saitēm utt. Pretējā gadījumā jūsu Outlook fails var viegli sabojāties. Šajā gadījumā pat iekšējais labošanas rīks nebūs daudz noderīgs. Ko jūs varat izmantot, ir tikai pieredzējusi ārēja lietderība, piemēram DataNumen Outlook Repair. Tā var noteikt PST failu bez piepūles.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp sabojāts sql un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar