Kā ātri eksportēt balsošanas statistiku no Outlook e-pasta uz Excel darblapu

Ja esat nosūtījis e-pastu ar balsošanas pogām, pēc tam, kad saņēmēji jums nosūtīs savas atbildes, iespējams, vēlēsities saskaitīt un eksportēt balsošanas statistiku Excel darblapā. Tātad, šajā lppost, mēs iemācīsim jums to ātri sasniegt.

Outlook ir tik spēcīga, ka tā piedāvā pat funkciju “Balsošana”. Mans iepriekšējais raksts “Prasmīga MS Outlook izmantošana balsošanai”Ir mācījis, kā to efektīvi izmantot. Arī most Pēc balsošanas dažu iemeslu dēļ, piemēram, vēlaties izdrukāt statistiku, varat turpināt eksportēt balsošanas statistiku uz Excel darblapu. Bet Outlook to pēc noklusējuma neatbalsta. Tādējādi turpmāk mēs iemācīsim jums to realizēt kā korķi.

Eksportēt balsošanas statistiku e-pastā uz Excel darblapu

1. Pašā sākumā palaidiet programmu Outlook.
2. Pēc tam Outlook galvenajā logā jānospiež taustiņu pogas “Alt + F11”.
3. Pēc tam logā “Microsoft Visual Basic for Applications” jāaktivizē “Microsoft Excel Object Library ”. Noklikšķiniet uz “Tools”> “Reference”. Pēc tam uznirstošajā dialoglodziņā atzīmējiet izvēles rūtiņu “Microsoft Excel Object Library ”un beidzot nospiediet“ OK ”.
4. Pēc tam jūs varat ievietot jaunu moduli vai atvērt neizmantotu moduli.
5. Pēc tam nokopējiet un ielīmējiet šajā modulī šādus VBA kodus.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Pēc tam ērtākai piekļuvei labāk pievienojiet jauno makro ātrās piekļuves rīkjoslai.
6. Galu galā jūs varat izmēģināt.

• Pirmkārt, atlasiet avota e-pastu, kurā ir balsošanas pogas.
• Pēc tam ātrās piekļuves rīkjoslā noklikšķiniet uz makro pogas.
• Pēc šī makro darbības beigām varat pārlūkot iepriekš noteiktu vietējo mapi, kurā redzēsit jaunu Excel darbgrāmatu.
• Atveriet šo Excel darbgrāmatu. Tagad jūs redzēsiet balsošanas statistiku, kas parādīta kā attēls:

Neviens nevar pamatīgi novērst Outlook kļūdas

Lai gan programma Outlook ir aprīkota ar dažādām iespējām, nav šādas funkcijas, kas palīdzētu mums izvairīties no Outlook kļūdām. Visu veidu faktori var izraisīt Outlook kļūdas. Piemēram, ja bieži iziet no programmas Outlook nepareizi, jūs, visticamāk, cietīsit PST korupcija. Šādā scenārijā jums nav citas izvēles, kā izmantot dažus spēcīgus rīkus, piemēram, lai glābtu savu PST failu DataNumen Outlook Repair. Tā ir nopelnījusi daudz slavas, pateicoties augstajam atkopšanas līmenim.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp korumpēts mdf un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar