Kā ātri eksportēt kopējo laiku, kas pavadīts Outlook tikšanās reizēs katrā krāsu kategorijā

Ja vēlaties izveidot pārskatu par kopējo laiku, ko tērējat tikšanās reizēm katrā krāsu kategorijā, varat izmantot šajā rakstā ievadīto metodi. Tas var palīdzēt jums to paveikt ātri, bez vajadzības skaitīt manuāli.

Daudzi lietotāji ir pieraduši reģistrēt lielāko daļu savu darbību Outlook kalendārā. Turklāt, lai tās būtu vieglāk pārvaldīt un atšķirt, viņi katrai no tām piešķir kategorijas. Šajā gadījumā daži lietotāji vēlas ģenerēt pārskatu, kurā redzams kopējais laiks, kas pavadīts kalendāra vienumiem katrā krāsu kategorijā. Nav šaubu, ka manuāla skaitīšana un ievadīšana ir apgrūtinoša. Tāpēc šeit mēs dalīsimies ar veidu, kā šo uzdevumu var paveikt ar vienkāršu klikšķi.

Eksportēt tikšanās laikā pavadīto laiku katrā krāsu kategorijā

1. Pirmkārt, palaidiet savu Outlook lietojumprogrammu.
2. Pēc tam, ievadot Outlook logu, jūs varētu pieskarties taustiņu pogām “Alt + F11”.
3. Pēc tam jūs saņemsiet piekļuvi logam “Microsoft Visual Basic for Applications”.
4. Pēc tam jums būs jāiespējo “Microsoft Excel objektu bibliotēka”. Lai to izdarītu, varat noklikšķināt uz “Rīki” > “Atsauce”.
5. Pēc tam jums jāatrod un jāatver modulis, kas netiek izmantots.
6. Pēc tam šajā modulī ir jākopē šāds VBA kods.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Visbeidzot, jūs varat aktivizēt šo makro, neatkarīgi no tā, rīkjoslā noklikšķinot uz ikonas “Palaist” vai nospiežot taustiņa “F5” taustiņu.
8. Pēc tam jums tiks prasīts izvēlēties konkrētu kalendāru.
9. Pēc tam, kad esat atlasījis un nospiedis “OK”, makro turpinās darboties. Pēc tā pabeigšanas būs jauns Excel fails, kas tiek parādīts fonā.
10. Jūs varat tai piekļūt. Tas izskatīsies kā šāds ekrānuzņēmums:

Sekojiet līdzi iespējamiem draudiem ap savu Outlook

Outlook lietotājiem būtu jāuzmanās no visiem iespējamiem riskiem, tostarp nezināmiem e-pasta pielikumiem, iegultām saitēm un cilvēku kļūdām. Pretējā gadījumā jūsu Outlook var tikt bojāta jebkurā laikā. Nepieciešamība ir arī regulāru Outlook datu dublēšana un specializēta remonta rīka glabāšana. DataNumen Outlook Repair ir viens no visieteicamākajiem labošanas rīkiem. Tas var labot Outlook problēmas vienā mirklī.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp bojāts mdf un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar