Kā ātri eksportēt visu PST failā esošo mapju lieluma informāciju uz Excel failu

Ja vēlaties pārbaudīt katras PST faila mapes lieluma informāciju, varat izmantot šajā rakstā aprakstīto metodi. Tas ātri eksportēs visu PST failā esošo mapju lieluma informāciju uz Excel failu.

Kad jūsu PST fails ir pārāk liels, ieteicams pārbaudīt katras mapes lielumu. Tas palīdzēs jums viegli noskaidrot, kuri ir lielāki, un veikt piemērotu arhivēšanu, ņemot vērā lielumu. Kopumā, lai pārbaudītu mapes lielumu, varat vienkārši ar peles labo pogu noklikšķināt uz mapes un pēc tam izvēlēties “Properties”. Jaunajā uznirstošajā dialoglodziņā varat noklikšķināt uz pogas “Mapes lielums”. Tomēr, ja esat izveidojis daudzas mapes, lieluma informācijas manuāla pārbaude pa vienam ir ievērojami apgrūtinoša. Tātad, ja vēlaties sērijveidā iegūt visu PST faila mapju lieluma informāciju, varat izmantot šādu VBA kodu. Tas vienā reizē eksportēs visus mapju nosaukumus un lieluma informāciju uz Excel failu.

Eksportējiet visu PST failā esošo mapju lieluma informāciju uz Excel failu

1. Lai sāktu, palaidiet savu Outlook lietojumprogrammu.
2. Pēc tam pārejiet uz cilni “Izstrādātājs” un noklikšķiniet uz pogas “Visual Basic” vai nospiediet taustiņus “Alt + F11”, lai piekļūtu VBA redaktoram.
3. Pēc tam logā “Microsoft Visual Basic for Applications” atveriet moduli, kas netiek izmantots.
4. Pēc tam nokopējiet un ielīmējiet šajā modulī šādus VBA kodus.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Pēc tam jums vajadzētu iestatīt zemu Outlook makro drošības līmeni.
6. Galu galā jūs varat izmēģināt.

• Pašreizējā makro logā nospiediet taustiņu F5.
• Tad jums tiks lūgts atlasīt PST failu, piemēram, šo attēlu:
• Pēc avota faila izvēles programma Outlook sāks eksportēt informāciju par izmēru uz programmu Excel.
• Pēc makro pabeigšanas jūs saņemat ziņojumu, piemēram, zemāk redzamo ekrānuzņēmumu.
• Visbeidzot, Excel failu varēsiet atrast iepriekš noteiktā vietējā mapē. Excel fails izskatīsies šādi:

Nodarbojieties ar biežām PST kļūdām

Tā kā Outlook ir tendence uz kļūdām, iespējams, kādreiz esat saskāries ar daudzām problēmām savā Outlook. Lai labāk un elastīgāk tiktu galā ar nomāktajām PST nepatikšanām, ieteicams tuvumā turēt pieredzējušu un cienījamu labošanas rīku, piemēram, DataNumen Outlook Repair. Tas ir spējīgs noteikt PST tādas problēmas kā vēsma.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp SQL Server atgūšana un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar