Kā ātri konvertēt visus iegultos attēlus pielikumos jūsu Outlook e-pastā

Ja vēlaties ātri mainīt visus ziņojuma pamattekstā iegultos attēlus uz e-pasta pielikumiem, jums nav manuāli jānoņem un jāpievieno atkārtoti. Varat vienkārši izmantot šajā rakstā redzamo VBA koda daļu.

Dažreiz, iespējams, vēlēsities visus iegultos attēlus pārvērst pielikumos. Piemēram, pārāk daudz attēlu ziņojuma pamattekstā traucēs lasīt tekstu pamattekstā. Tāpēc vēlaties tos noņemt no e-pasta pamatteksta un pievienot kā pielikumus. Protams, to var izdarīt manuāli. Bet tam ir jābūt ērtākam, ja ar kādiem rīkiem vai VBA kodiem to var iegūt vienā piegājienā. Šeit mēs jums atklāsim šādu VBA kodu.

Ātri konvertējiet visus iegultos attēlus pielikumos

1. Pirmkārt, startējiet savu Outlook programmu.
2. Pēc tam varat pārslēgties uz cilni “Izstrādātājs” un nospiest pogu “Visual Basic”.
3. Tālāk jūs nokļūsit Outlook VBA redaktora logā.
4. Pēc tam jums ir jākopē šis VBA kods tukšā modulī.

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Pēc tam jums vajadzētu apstiprināt, ka programma Outlook ir iestatīta, lai atļautu makro.
6. Ja jums tas bieži ir nepieciešams, labāk ir pievienot jauno makro ātrās piekļuves rīkjoslai turpmākai ērtai pārbaudei.
7. Galu galā jūs varat mēģināt. Atlasiet vai atveriet e-pastu un pēc tam palaidiet makro, ātrās piekļuves rīkjoslā noklikšķinot uz jaunā makro pogas.
8. Tūlīt visi iegultie attēli tiks mainīti uz pielikumiem, kā parādīts šādā ekrānuzņēmumā:

Padomi jūsu vērtīgo Outlook datu aizsardzībai

Kā mēs visi zinām, Outlook PST fails ir tikpat neaizsargāts kā parastie faili, piemēram, Word dokumenti vai Excel izklājlapas. Tāpēc jums ir jāuzrauga visi riski, kas saistīti ar jūsu PST failu, piemēram, vīrusi vai nepareiza apstrāde. Tāpēc jums regulāri jāveido sava PST faila datu dublējumkopijas. Turklāt, ja varat to atļauties, ir prātīgi saglabāt izturīgu Outlook remonts rīks ērts, piemēram DataNumen Outlook Repair.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp atgūt mdf un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar