Kā ātri saspiest visus pielikumus a Zip Fails jūsu Outlook e-pastā

Kopīgot tūlīt:

Dažreiz jūs varētu vēlēties visus e-pasta pielikumus saspiest zip failu tieši programmā Outlook. Šajā gadījumā, lai sasniegtu šo funkciju, varat izmantot šajā rakstā ievadīto VBA kodu.

Pēc noklusējuma programmai Outlook ir noteikts pielikumu lieluma ierobežojums - 20 MB POP3, IMAP vai citiem tīmekļa e-pasta kontiem un 10 MB Exchange kontiem. Tātad, kad pielikumu kopējais lielums pārsniedz ierobežojumu, jūs saņemsiet saistītas kļūdas. Šajā gadījumā tā ir laba iespēja visus pielikumus saspiest a zip fails.

Ātri saspiediet visus pielikumus a Zip Fails jūsu Outlook e-pastā

Tomēr, kā redzat, programma Outlook nepiedāvā tik tiešu funkciju. Tas nozīmē, ka jums vispirms ir nepieciešams zip šos failus cietajā diskā un pēc tam atkārtoti pievienojiet jaunizveidoto zip fails. Patiesībā lielākā daļa lietotāju cer, ka to varēs tieši paveikt programmā Outlook. Lai apmierinātu šo prasību, mēs turpmāk aprakstīsim, kā to realizēt, izmantojot VBA.

Saspiest visus pielikumus a Zip fileja

  1. Pirmkārt, palaidiet savu Outlook lietojumprogrammu.
  2. Pēc tam Outlook galvenajā logā nospiediet taustiņu “Alt + F11” taustiņus.
  3. Pēc tam jaunajā Outlook VBA redaktora logā atveriet moduli.
  4. Pēc tam kopējiet un ielīmējiet modulī šādus VBA kodus.
Sub ZipAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim objShell As Object
    Dim varTempFolder As Variant
    Dim varZipFile As Variant
 
    'Save the attachments to Temporary folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    varTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "dd-mm-yyyy- hh-mm-ss-")
    MkDir (varTempFolder)
    varTempFolder = varTempFolder & "\"
 
    Set objMail = Outlook.Application.ActiveInspector.CurrentItem
    Set objAttachments = objMail.attachments
    For Each objAttachment In objAttachments
        objAttachment.SaveAsFile (varTempFolder & objAttachment.FileName)
    Next
 
    'Create a new zip file
    varZipFile = InputBox("Specify a name for the new zip file", "Name Zip File", objMail.Subject)
    varZipFile = objFileSystem.GetSpecialFolder(2).Path & "\" & varZipFile & ".zip"
    Open varZipFile For Output As #1
    Print #1, Chr$(80) & Chr$(75) & Chr$(5) & Chr$(6) & String(18, 0)
    Close #1
 
    'Copy all the saved attachments to the new zip file
     Set objShell = CreateObject("Shell.Application")
     objShell.NameSpace(varZipFile).CopyHere objShell.NameSpace(varTempFolder).Items

     'Keep macro running until Compressing is done
     On Error Resume Next
     Do Until objShell.NameSpace(varZipFile).Items.Count = objShell.NameSpace(varTempFolder).Items.Count
        Application.Wait (Now + TimeValue("0:00:01"))
     Loop
     On Error GoTo 0
 
     'Delete all the attachments
     Set objAttachments = objMail.attachments
     While objAttachments.Count > 0
           objAttachments.Item(1).Delete
     Wend
 
     'Add the new zip file to the current email 
     objMail.attachments.Add varZipFile
 
    'Prompt
    MsgBox ("Complete!")
End Sub

VBA kods - ātri saspiest visus pielikumus a Zip Fails jūsu Outlook e-pastā

  1. Pēc tam jums jāpārbauda Outlook makro iestatījumi, lai pārliecinātos, ka makro ir atļauts.
  2. Vēlāk jauno VBA projektu kā parasti varat pievienot ziņojuma loga ātrās piekļuves rīkjoslai.
  3. Galu galā jūs varat izmēģināt.
  • Pirmkārt, izveidojiet jaunu e-pastu un pievienojiet vairākus failus. Vai vienkārši atveriet pastu ar daudziem pielikumiem.
  • Pēc tam ātrās piekļuves rīkjoslā noklikšķiniet uz pogas makro.
  • Vēlāk jums jānorāda nosaukums zip failu un nospiediet “OK”. Pēc noklusējuma tas tiks iestatīts tāpat kā pasta tēma.Norādiet nosaukumu zip fails
  • Uzreiz visi pielikumi tiks saspiesti a zip failu, piemēram, šo ekrānuzņēmumu:Saspiest visus pielikumus a Zip fileja

Atskrūvējiet rāvējslēdzēju .Zip Pielikumi tieši programmā Outlook

Ir neizbēgami, ka jūs saņemsiet jebkādus pielikumus ar “.zip"faila paplašinājumu ik pa laikam. Šādā gadījumā jūs, iespējams, vēlēsities tieši atzipēt šādus failus no savas programmas Outlook, nevis saglabāt un atspiest tos lokālajā diskā. Lai gan programmai Outlook nav šādas iebūvētas funkcijas, jūs joprojām varat izmantot arī VBA, lai to iegūtu. Sīkāku informāciju varat atrast citā rakstā — "Kā atvilkt rāvējslēdzēju .Zip Pielikumi tieši programmā Outlook, izmantojot VBA".

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp sql labot un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar

Kopīgot tūlīt:

Komentāri ir slēgti.