Kā parādīt atbilstošo personu vecumu visiem dzimšanas dienas notikumiem Outlook kalendāra saraksta skatā

Daži lietotāji, skatot kalendārā dzimšanas dienas notikumu, vēlas redzēt arī attiecīgās personas vecumu. Tāpēc šajā rakstā mēs dalīsimies ar metodi, kā viegli īstenot šo ideju.

Kad kontaktpersonai pievienojat dzimšanas dienas informāciju, programma Outlook automātiski izveidos dzimšanas dienas notikumu kalendārā. Šādā gadījumā katru reizi, kad kalendārā redzat dzimšanas dienas pasākumus, iespējams, vēlēsities iegūt arī atbilstošo personu vecumu. Tādējādi šeit mēs iepazīstināsim jūs ar veidu, kā to realizēt.

Parādiet atbilstošo personu vecumu visiem dzimšanas dienas pasākumiem saraksta skatā

1. Pašā sākumā palaidiet Outlook VBA redaktoru.
2. Pēc tam modulī iekopējiet šo kodu.

Sub ShowAgesOfBirthdayEventsListView()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Process All Calendar Folders in Your Outlook
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olAppointmentItem Then
               Call ProcessFolders(objFolder)
            End If
        Next
    Next
End Sub

Sub ProcessFolders(ByVal objCalendar As Outlook.Folder)
    Dim i As Integer
    Dim objItem As Object
    Dim objBirthdayEvent As Outlook.AppointmentItem
    Dim dStart, dBirth As Date
    Dim nAge As Integer
    Dim objNewProperty As Outlook.UserProperty
    Dim objSubCalendar As Outlook.Folder

    For i = objCalendar.Items.Count To 1 Step -1
        Set objItem = objCalendar.Items.Item(i)
        'Add "Age" Property to Birthday Events
        If (objItem.MeetingStatus = olNonMeeting) And (objItem.IsRecurring = True) And (Right(objItem.Subject, 11) = "'s Birthday") Then
           Set objBirthdayEvent = objItem
           dStart = objBirthdayEvent.Start
 
           'Count Age
           dCurrentBirthday = DateSerial(Year(Now), Month(dStart), Day(dStart))
           nAge = DateDiff("yyyy", dStart, dCurrentBirthday)
 
           Set objNewProperty = objBirthdayEvent.UserProperties.Find("Age", True)
           If objNewProperty Is Nothing Then
              Set objNewProperty = objBirthdayEvent.UserProperties.Add("Age", olText, True)
           End If
 
           objNewProperty.value = nAge
           objBirthdayEvent.Save
        End If
    Next
 
    'Process All Sub-Calendar Folders Recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call ProcessFolders(objSubCalendar)
       Next
    End If
End Sub

3. Pēc tam novietojiet kursoru pirmajā apakšprogrammā un nospiediet "F5", lai palaistu šo makro.
4. Kad makro ir pabeigts, izejiet no VBA redaktora un atveriet kalendāra mapi.
5. Pēc tam dodieties uz cilni “Skats” un noklikšķiniet uz “Mainīt skatu” > “Saraksts”.
6. Pēc tam noklikšķiniet uz pogas Skatīt iestatījumus.
7. Uznirstošajā dialoglodziņā izvēlieties "Slejas".
8. Pēc tam nākamajā dialoglodziņā “Rādīt kolonnas” sarakstā “Atlasīt pieejamos laukus no” atlasiet “Lietotāja definētie lauki mapē”.
9. Vēlāk lodziņā “Pieejamās slejas” norādiet “Vecums” un noklikšķiniet uz pogas “Pievienot ->”.
10. Galu galā noklikšķiniet uz "OK" sērijas, līdz atgriezīsities kalendāra vienumu sarakstā.
11. Tagad sarakstā varat redzēt visu dzimšanas dienu notikumu personu vecumu, kā parādīts nākamajā attēlā.

Labojiet apdraudēto Outlook failu

Satiekoties, jums var rasties panika korumpēta Outlook failu, kurā ir daudz jūsu vērtīgo e-pasta ziņojumu un grafiku. Neskatoties uz to, ka šāds jautājums ir diezgan izmisīgs, jums tomēr nekavējoties jānomierinās un jāapsver efektīvi pasākumi. Ja turpināsit uztraukties, situācija var pasliktināties un pasliktināties. Faktiski ir vairāki veidi un utilītas, kas var labot bojāto failu, piemēram, iesūtnes labošanas rīks un izturīgāks un pieredzējušāks rīks, piemēram, DataNumen Outlook Repair.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp SQL Server noteikts un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar