Kā automātiski izmantot dažādas fontu krāsas, lai atbildētu un pārsūtītu e-pastus ar Outlook VBA

Outlook risinājumi Septembris 29, 2025
Kopīgot tūlīt:

Pēc noklusējuma jūs nevarat ļaut programmai Outlook automātiski izmantot dažādas fontu krāsas, lai atbildētu un pārsūtītu e-pastus. Tādēļ, ja jums ir šāda prasība, varat izlasīt šo lppost lai iemācītos gudru pieeju.

Programma Outlook ļauj jums norādīt tikai fontu, kas tiek izmantots gan e-pasta ziņojumu atbildēšanai, gan pārsūtīšanai. Jūs varat pāriet uz “File”> “Options”. Pēc tam sadaļā “Outlook opcijas” pārejiet uz cilni “Mail” un noklikšķiniet uz pogas “Stationery and Fonts…”. Nākamajā logā sadaļā Ziņojumu atbildēšana vai pārsūtīšana var redzēt pogu “Fonts”. Noklikšķiniet uz tā, un pēc tam varat iestatīt noteiktu fonta krāsu, lai atbildētu un pārsūtītu e-pastus.

Mainīt fontu, atbildot vai pārsūtot ziņojumus

Tomēr daudzi lietotāji cer izmantot dažādas fontu krāsas, lai atbildētu vai pārsūtītu e-pastus. Lai gan programma Outlook tam nenodrošina tiešas funkcijas, to joprojām var realizēt ar VBA kodu. Tagad lasiet tālāk, lai iegūtu šādu VBA koda daļu.

Automātiski izmantot dažādas fontu krāsas, lai atbildētu un pārsūtītu e-pastus

  1. Par kātart, palaidiet programmu Outlook.
  2. Pēc tam aktivizējiet VBA redaktoru, atsaucoties uzKā palaist VBA kodu programmā Outlook".
  3. Pēc tam saskaņā arKā pievienot objektu Library Atsauce VBA“, Pievienojiet atsauci uz„ MS Word Object Library ”.
  4. Pēc tam nokopējiet šo kodu projektā “ThisOutlookSession”.
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

VBA kods - automātiski izmantojiet dažādas fontu krāsas, lai atbildētu un pārsūtītu e-pastus

  1. Pēc tam reztart Outlook, lai aktivizētu šo makro.
  2. Visbeidzot, jūs varat izmēģināt.
  • Atlasiet vai atveriet e-pastu.
  • Pēc tam noklikšķiniet uz pogas Atbildēt. Atbildot uz e-pastu, jūs varat ierakstīt dažus vārdus pamattekstā. Fonta krāsai jābūt rozā krāsā."Rozā" fonts sadaļā "Atbildēt"
  • Vai noklikšķiniet uz pogas Atbildēt visiem. Jaunajā “atbildot uz visiem” pastā ievadiet vārdus pamattekstā. Fonta krāsa noteikti ir zaļa."Zaļais" fonts sadaļā "Atbildēt visiem"
  • Tāpat noklikšķiniet uz pogas “Pārsūtīt”. Pārsūtīšanas pastā jaunie vārdi tiks parādīti zilā krāsā.Fonts "Zils" sadaļā "Pārsūtīt"

Izmantojiet uzticamu programmatūru

Ja notiek Outlook korupcija, Most lietotāji mēdz izmantot Outlook atkopšanas programmatūru. Tirgū ir pieejams ļoti daudz šādu programmu. Un daži no tiem ir pat bez maksas. Neskatoties uz to, jums vajadzētu piesargāties no nezināmiem avotiem, jo ​​tie var padarīt šo lietu vēl sliktāku. Jums vajadzētu izmantot uzticamu un pieredzējušu rīku, piemēram, DataNumen Outlook Repair.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp sabojāts sql un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar

Kopīgot tūlīt:

Komentāri ir slēgti.