Kā sūtīt visas darblapas vienā Excel darbgrāmatā kā atsevišķus Outlook e-pastus

Ja vēlaties visas darblapas Excel darbgrāmatā nosūtīt kā atsevišķus Outlook e-pasta ziņojumus, varat izmantot šajā rakstā ievadīto metodi. Tas var palīdzēt jums to realizēt vairumā, bez grūtībām sūtot pa vienam.

Manā iepriekšējā ierakstā “2 ātras metodes Excel darblapas nosūtīšanai kā Outlook e-pastu”, jūs varat uzzināt divus veidus, kā nosūtīt vienu Excel darblapu kā e-pastu. Ja vēlaties nosūtīt visas darblapas vienā darbgrāmatā kā atsevišķus e-pastus, jebkura no diviem šajā ierakstā minētajiem veidiem izmantošana būs diezgan nogurdinoša un apgrūtinoša. Tādēļ šeit mēs iepazīstināsim ar citu veidu, kā ātri īstenot šādu “partijas sūtīšanu”.

Sūtīt visas darblapas vienā Excel darbgrāmatā kā atsevišķus e-pastus

1. Pirmkārt, jums jāatver avota Excel darbgrāmata.
2. Pēc tam, ievadot Excel logu, jums jāpieskaras taustiņu saīsnēm “Alt + F11”.
3. Pēc tam tiks parādīts vēl viens logs ar nosaukumu “Microsoft Visual Basic for Applications”.
4. Tajā jums jāatver neizmantots modulis vai jāievieto jauns modulis.
5. Pēc tam šajā modulī varat kopēt šādu VBA kodu.

Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

6. Pēc tam jūs varētu aktivizēt šo makro, nospiežot taustiņu F5 vai rīkjoslā noklikšķinot uz ikonas “Palaist”.
7. Vienlaikus e-pasta ziņojumi, kas atbilst visām šīs Excel darbgrāmatas darblapām, tiks parādīti programmā Outlook.
8. Visbeidzot, jūs varat vēlreiz pārbaudīt visu e-pasta ziņojumu informāciju un visbeidzot noklikšķiniet uz pogas Sūtīt, lai nosūtītu e-pastus.

Ja nav dublējumu, lietojiet spēcīgas atkopšanas rīku

Arvien vairāk lietotāju ir sapratuši datu dublējumu nozīmi. Kamēr esat dublējis savu PST failu, PST atkopšana pēc bojājumiem būs diezgan vienkārši. Bet, ja nav efektīvas un atjauninātas PST dublēšanas, jums nekas cits neatliek kā izmantot ārējā PST labošanas rīka palīdzību, piemēram, DataNumen Outlook Repair. Tas var labot apdraudētos PST failus kā brīze.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp atgūt kv un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar