Kā automātiski iestatīt atšķirīgu atgādinājumu laiku Outlook sanāksmēm dažādās krāsu kategorijās

Ja klasificējat Outlook sapulces pēc krāsu kategorijām un vēlaties iestatīt atšķirīgu atgādinājumu laiku sapulcēm dažādās krāsu kategorijās, varat atsaukties uz šo rakstu. Šeit mēs iemācīsim jums to realizēt, izmantojot Outlook VBA.

Piemēram, jūs sadalāt sanāksmes divās grupās. Viena ir krāsu kategorijā “Ārpus telpām”, jo sanāksmes vieta ir pārāk tālu, bet otra ir krāsu kategorijā “Klātienē”, jo vieta ir tieši šeit. Tagad jūs vēlaties, lai Outlook varētu automātiski iestatīt atgādinājuma laiku “ārpus telpām” notiekošajai sanāksmei 1 stundu pirms sākuma un “klātienē” notiekošajai sanāksmei 15 minūtes pirms sākuma. Aplūkojot šo prasību, turpmāk mēs dalīsimies ar ātru metodi.

Automātiski iestatīt atšķirīgu atgādinājumu par sapulcēm dažādās krāsu kategorijās

1. Vispirms palaidiet programmu Outlook.
2. Pēc tam nospiediet taustiņu “Alt + F11” taustiņus, lai piekļūtu VBA redaktora logam.
3. Pēc tam nākamajā logā nokopējiet un ielīmējiet zemāk esošo VBA kodu projektā “ThisOutlookSession”.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Vēlāk jums jānoklikšķina uz apakšprogrammas “Application_Startup” un jānospiež taustiņš “F5”, lai palaistu šo makro.
5. Kopš tā laika katru reizi, kad noklusējuma kalendāram tiek pievienota jauna sapulce vai maināt esošu sapulci, Outlook automātiski pārbaudīs sapulces kategorijas un automātiski iestatīs atšķirīgo atgādinājuma laiku.

Novērst Outlook kļūdas

Programmā Outlook laiku pa laikam var rasties dažādas problēmas. Tāpēc lietotājiem ir ārkārtīgi svarīgi iemācīties tikt galā ar Outlook problēmām. Sākumā ieteicams regulāri dublēt Outlook datus. Turklāt, ja iespējams, ieteicams uzturēt spēcīgu rezerves kopiju. Outlook remonts rīks tuvumā, piemēram, DataNumen Outlook Repair. Tas var skenēt jūsu PST failu, lai noskaidrotu Outlook problēmas un pēc tam tos viegli atrisinātu.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp sql atgūšana un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar