Kā automātiski noņemt sākotnējo sūtītāju un saņēmēju e-pasta adreses, pārsūtot Outlook e-pastu

Pārsūtot e-pastu programmā Outlook, sākotnējā sūtītāja un saņēmēju e-pasta adreses tiks iekļautas ziņojuma pamattekstā. Šobrīd drošības apsvērumu dēļ labāk ir noņemt šīs adreses. Šajā ierakstā ir paskaidrots, kā ļaut programmai Outlook to izdarīt automātiski.

Daudzos gadījumos daži e-pasta ziņojumi būs jāpārsūta kādam citam. Pēc noklusējuma sākotnējā e-pasta ziņojuma galvene tiks parādīta pārsūtīšanas e-pasta pamattekstā. Galvenē būs sākotnējā sūtītāja un saņēmēja e-pasta adreses. Drošības vai privātuma labad jūs varētu vēlēties noņemt šīs e-pasta adreses. Tomēr ir pārāk garlaicīgi tos manuāli noņemt. Tādēļ šeit mēs palīdzēsim jums izveidot programmu Outlook, lai automātiski veiktu šo uzdevumu jūsu vārdā.

Automātiski noņemiet sākotnējo sūtītāju un saņēmēju e-pasta adreses, pārsūtot e-pastu

1. Lai sāktu, palaidiet programmu Outlook.
2. Pēc tam nospiediet taustiņu “Alt + F11” taustiņus, lai piekļūtu VBA redaktoram.
3. Pēc tam kopējiet šo VBA kodu projektā “ThisOutlookSession”.

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objRegExp As Object
    Dim strHTMLBody As String
 
    Forward.Display
    strHTMLBody = Forward.HTMLBody
 
    'Find email addresses in the body via Regular Expression
    Set objRegExp = CreateObject("vbscript.RegExp")
    With objRegExp
        .Pattern = "(?:[a-z0-9!#$%&'*+/=?^_`{|}~-]+(?:\.[a-z0-9!#$%&'*+/=?^_`{|}~-]+)*|""(?:[\x01-\x08\x0b\x0c\x0e-\x1f\x21\x23-\x5b\x5d-\x7f]|\\[\x01-\x09\x0b\x0c\x0e-\x7f])*"")@(?:(?:[a-z0-9](?:[a-z0-9-]*[a-z0-9])?\.)+[a-z0-9](?:[a-z0-9-]*[a-z0-9])?|\[(?:(?:25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?)\.){3}(?:25[0-5]|2[0-4][0-9]|[01]?[0-9][0-9]?|[a-z0-9-]*[a-z0-9]:(?:[\x01-\x08\x0b\x0c\x0e-\x1f\x21-\x5a\x53-\x7f]|\\[\x01-\x09\x0b\x0c\x0e-\x7f])+)\])"
        .IgnoreCase = True
        .Global = True
    End With
 
    'Remove email addresses
    If objRegExp.Test(strHTMLBody) Then
       Set objFoundResults = objRegExp.Execute(strHTMLBody)
       For i = 1 To objFoundResults.Count
           Forward.HTMLBody = Replace(Forward.HTMLBody, objFoundResults.Item(i - 1).Value, "")
       Next
    End If
 
    'Remove useless characters
    Forward.HTMLBody = Replace(Forward.HTMLBody, "[mailto:]", "")
    Forward.HTMLBody = Replace(Forward.HTMLBody, "()", "")
End Sub

4. Pēc tam restartējiet programmu Outlook, lai aktivizētu šo jauno makro.
5. Galu galā jūs varat fotografēt:

• Atlasiet vai atveriet e-pastu.
• Pēc tam grupā “Atbildēt” noklikšķiniet uz pogas “Pārsūtīt”.
• Visbeidzot, tiks parādīts jauns pārsūtīšanas e-pasts, kurā sākotnējā sūtītāja un saņēmēja e-pasta adreses ir izdzēstas.

Nomierinieties perspektīvas korupcijas gadījumā

Ja jūs saskaraties ar jebkādām Outlook problēmām, jūs varat izbīties un baidīties Outlook korupcija. Tomēr, godīgi sakot, steiga un raizes parasti var izraisīt daudz citu jūsu Outlook problēmu. Tādēļ nekrīti panikā, bet attiecīgajos gadījumos esi mierīgs. Turklāt, ja esat saglabājis stabilu PST labošanas rīku, piemēram ,. DataNumen Outlook Repair, to var vienkārši izmantot, lai atrisinātu Outlook problēmas.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp labot kv un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar