2 veidi, kā izdrukāt Outlook uzdevumu sarakstus ar dažādām kategorijām dažādās lapās

Ja saviem Outlook uzdevumiem esat piešķīris dažādas krāsu kategorijas un tagad vēlaties dažādās lapās izdrukāt dažādu kategoriju uzdevumu sarakstus, varat atsaukties uz šo rakstu. Šeit mēs jums dalīsimies ar 2 metodēm.

Lai klasificētu un labi pārvaldītu savus uzdevumus, iespējams, uzdevumiem esat lietojis krāsu kategorijas. Tagad, ja vēlaties dažādās lapās izdrukāt savu uzdevumu sarakstus ar dažādām kategorijām, lūdzu, lasiet tālāk. Turpmāk mēs iepazīstināsim jūs ar 2 līdzekļiem, lai to iegūtu.

1. metode: manuāli izdrukāt uzdevumu sarakstus pa vienam

1. Pirmkārt, programmā Outlook piekļūstiet rūtim “Uzdevumi”.
2. Pēc tam atveriet mapi Uzdevums.
3. Pēc tam nospiediet taustiņu kombināciju “Ctrl + E”, lai aktivizētu lenti “Meklēt”.
4. Pēc tam cilnē “Meklēt” noklikšķiniet uz pogas “Kategorizēt”.
5. Nolaižamajā sarakstā izvēlieties krāsu kategoriju.
6. Tad sarakstā tiks atstāti tikai uzdevumi ar atlasīto kategoriju.
7. Tagad dodieties uz “File”> “Print”, lai izdrukātu šo uzdevumu sarakstu.
8. Pēc tam tādā pašā veidā pa vienam manuāli izdrukājiet uzdevumu sarakstus ar citām krāsu kategorijām.

2. metode: sērijveida izdrukāt VBA uzdevumu sarakstus

1. Jau pašā sākumā aktivizējiet VBA redaktoru saskaņā ar “Kā palaist VBA kodu programmā Outlook".
2. Pēc tam pievienojiet atsauci uz “MS Excel objektu bibliotēku”, kā norādīts “Kā pievienot objektu bibliotēkas atsauci VBA valodā".
3. Pēc tam modulī kopējiet šo VBA kodu.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Pēc tam nospiediet taustiņu “F5”, lai uzreiz palaistu šo makro.
5. Kad makro būs pabeigts, dažādu kategoriju uzdevumu saraksti tiks drukāti dažādās lapās, kā parādīts nākamajā ekrānuzņēmumā.

Iegūstiet atpakaļ vērtīgos datus no apdraudēta PST faila

Ja uz jums attiecas nepieejams PST fails, neapšaubāmi jūsu nākamā darbība ir PST remonts. Šajā gadījumā vispirms varat izmēģināt iesūtnes labošanas rīku. Ja neizdodas, varat turpināt izmēģināt citu ārēju rīku, piemēram, DataNumen Outlook Repair. Tas spēj ātri atgūt PST datus.

Autora ievads:

Šērlija Džana ir datu atkopšanas eksperte DataNumen, Inc., kas ir pasaules līderis datu atkopšanas tehnoloģiju, tostarp atgūt mdf un perspektīvas remonta programmatūras produktus. Lai iegūtu vairāk informācijas, apmeklējiet vietni www.datanumen. Ar