Kaip automatiškai išgauti įterptus vaizdus iš konkrečių gaunamų el. laiškų naudojant „Outlook VBA“.

Jei norite, kad „Outlook“ automatiškai ištrauktų ir išsaugotų įterptus vaizdus iš konkrečių gaunamų el. laiškų, galite peržiūrėti šį straipsnį. Čia mes išmokysime, kaip tai realizuoti naudojant VBA kodą.

Kai kuriems vartotojams dažnai reikia išskirti įterptus vaizdus iš konkrečių gaunamų el. laiškų ir išsaugoti juos tam tikrame „Windows“ aplanke. Taip sunku kiekvieną kartą tai padaryti rankiniu būdu. Todėl daugelis tikisi išmokti greitą ir patogų būdą, kaip leisti „Outlook“ tai padaryti automatiškai. Dabar mes pasidalinsime tokiu metodu su jumis.

Automatiškai išskleiskite įterptus vaizdus iš konkrečių gaunamų el. laiškų

1. Pirma, kaip įprasta, paleiskite „Outlook“ programą.
2. Tada, kaip įprasta, suaktyvinkite „Outlook VBA“ redaktorių su nuoroda t “Kaip paleisti VBA kodą „Outlook“.".
3. Vėliau nukopijuokite ir įklijuokite šį VBA kodą į projektą „ThisOutlookSession“.

Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

4. Po to spustelėkite „Application_Startup“ subrutiną.
5. Galiausiai spustelėkite „F5“, kad suaktyvintumėte šią makrokomandą.
6. Nuo šiol kiekvieną kartą, kai į gautuosius atkeliaus konkretus naujas el. laiškas, įterptieji vaizdai bus išsaugoti konkrečiame Windows aplanke, kaip parodyta toliau esančioje ekrano kopijoje.

Reguliariai valykite didelius priedus

Patartina reguliariai išvalyti didelius priedus iš „Outlook“. Taip siekiama išlaikyti tinkamą „Outlook“ failo dydį. Didesni „Outlook“ failai yra labiau pažeidžiami gedimų. Kaip žinote, PST pažeidimus gana sunku gerai ištaisyti. Galbūt pirmiausia pabandykite juos ištaisyti naudodami pašto dėžutės taisymo įrankį. Tačiau daugeliu atvejų tai nepadės. Vienintelė išeitis – specializuotas... PST remontas įrankis, pvz DataNumen Outlook Repair, arba atitinkamas profesionalias atkūrimo paslaugas.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant mdf taisymas ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com