Kaip paketais siųsti visus darbalapius vienoje „Excel“ darbaknygėje kaip atskirus „Outlook“ el

Jei norite siųsti visus „Excel“ darbaknygės darbalapius kaip atskirus „Outlook“ el. laiškus, galite naudoti šiame straipsnyje aprašytą metodą. Jis gali padėti jums tai realizuoti masiškai be varginančio siuntimo po vieną.

Mano ankstesniame įraše "2 greiti būdai, kaip siųsti „Excel“ darbalapį „Outlook“ el. paštu„“, galite sužinoti du būdus, kaip išsiųsti vieną „Excel“ darbalapį el. paštu. Jei norite siųsti visus vienos darbaknygės darbalapius kaip atskirus el. laiškus paketiniu būdu, bet kurio iš dviejų tame įraše paminėtų būdų naudojimas bus gana varginantis ir varginantis. Todėl čia pristatysime kitą būdą, kuris gali greitai įgyvendinti tokį „paketinį siuntimą“.

Siųskite visus darbalapius vienoje „Excel“ darbaknygėje kaip atskirus el

1. Pirmiausia turėtumėte atidaryti šaltinio „Excel“ darbaknygę.
2. Tada, įėję į „Excel“ langą, turėtumėte bakstelėti „Alt + F11“ sparčiuosius klavišus.
3. Tada bus rodomas kitas langas, vadinamas „Microsoft Visual Basic for Applications“.
4. Jame turite atidaryti nenaudojamą modulį arba įdėti naują modulį.
5. Vėliau į šį modulį galite nukopijuoti šį VBA kodą.

Sub SendEachWorksheet_inOutlookEmail()
    Dim objWorksheet As Excel.Worksheet
    Dim objRange As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        Set objRange = objWorksheet.UsedRange
        objRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)
 
        Set objOutlookApp = CreateObject("Outlook.Application")
        Set objMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objMail.HTMLBody = objTextStream.ReadAll
 
        'Change the email details as per your needs
        With objMail
             .To = "test@datanumen.com"
             .Subject = objWorksheet.Name
             .Display
        End With
 
        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
    Next
End Sub

6. Po to galite suaktyvinti šią makrokomandą paspausdami F5 klavišą arba įrankių juostoje spustelėdami piktogramą „Vykdyti“.
7. El. laiškai, atitinkantys visus šios „Excel“ darbaknygės darbalapius, iškart bus rodomi „Outlook“.
8. Galiausiai galite dar kartą patikrinti visą el. laiškų informaciją ir galiausiai spustelėti mygtuką „Siųsti“, kad išsiųstumėte el. laiškus.

Jei nėra atsarginių kopijų, naudokite galingą atkūrimo įrankį

Vis daugiau vartotojų suprato duomenų atsarginių kopijų svarbą. Kol sukūrėte atsarginę PST failo kopiją, PST atkūrimas po žalos bus gana paprasta. Tačiau jei nėra veiksmingos ir naujausios PST atsarginės kopijos, jums nelieka nieko kito, kaip tik pasinaudoti išoriniu PST taisymo įrankiu, pvz. DataNumen Outlook Repair. Jis gali lengvai pataisyti pažeistus PST failus.

Autoriaus įvadas:

Shirley Zhang yra duomenų atkūrimo ekspertė DataNumen, Inc., kuri yra pasaulyje duomenų atkūrimo technologijų lyderė, įskaitant atkurti sql ir „Outlook“ taisymo programinės įrangos produktai. Norėdami gauti daugiau informacijos, apsilankykite WWW.datanumen.com