Outlook бағдарламасындағы ескірген күнтізбе элементтерінен тіркемелерді қалай жоюға болады

Егер Outlook бағдарламасында ескірген кездесулер мен кездесулерден тіркемелерді алып тастағыңыз келсе, сіз бұл мақаланы оқи аласыз. Мұнда біз сізге оны бір уақытта қалай жүзеге асыру керектігін ұсынамыз.

Outlook файлының өлшемін азайту үшін ескі элементтерді тазартқан жөн. Мұны ескі элементтерді белгілі бір уақыт аралығында автоматты түрде жоя алатын «AutoArchive» мүмкіндігі арқылы жүзеге асыруға болады. Дегенмен, кейбір пайдаланушылар ескі элементтердегі тіркемелерді элементтерге әсер етпей жойғысы келеді. Келесіде біз сізге ескі күнтізбе элементтерінен тіркемелерді жаппай жоюды үйретеміз.

Ескірген күнтізбе элементтерінен тіркемелерді алып тастаңыз

1. Алдымен Outlook VBA редакторына «Alt + F11» арқылы кіріңіз.
2. Содан кейін, «Microsoft Visual Basic for Applications» терезесінде VBA кодын модульге көшіріңіз.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Содан кейін «BatchDeleteAttachmentsOfOldCalendarItems» макросына басыңыз.
4. Осы макросты іске қосу үшін «F5» батырмасын басыңыз.
5. Макрос аяқталған кезде Outlook күнтізбелерінің барлығын тексеруге болады.
6. Outlook 2 айдан асқан күнтізбе элементтерінің барлық тіркемелерін жойған болуы керек.

Outlook бағдарламасының бұзылған файлдарымен күресу

Сіз Outlook жемқорлықпен кездестіңіз бе? Сіз әдетте оны қалай тастайсыз? Көбінесе сіз алдымен кіріс жәшігін жөндеу құралын қолданып көресіз - Сканерлеу. Бірақ, PST елеулі зақымданған жағдайда, кіріктірілген қызметтік бағдарлама сізге көмектесе алмайды. Осылайша жақын жерде тәжірибелі және керемет үшінші тарап құралын сақтау ұсынылады DataNumen Outlook Repair.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. квадрат жөндеу және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com