Outlook бағдарламасында электрондық пошта мекенжайынсыз барлық контактілерді пакеттік жоюдың 2 әдісі

Егер Outlook бағдарламасында кейбір контактілердің электрондық пошта мекенжайы жоқ екенін байқасаңыз, барлық осындай контактілерді жою үшін әрбір Контакт қалтасын өңдеуіңіз керек болуы мүмкін. Бұл жазба сізбен екі тәсілмен бөліседі.

Мүмкін сіздің Outlook бағдарламасында көптеген контактілер бар және олардың кейбіреулерінде электрондық пошта мекенжайы жоқ. Егер олар енді пайдалы емес деп ойласаңыз, электрондық пошта мекенжайы жоқ барлық контактілерді жоюға үміттенуіңіз керек. Стандартты жолмен оларды табу үшін «Лездік іздеуді» пайдалануға болады, содан кейін оларды келесі 1-әдіс сияқты қолмен жоюға болады. Дегенмен, бұл біраз жалықтырады. Сондықтан 2-әдісте біз сізге басқа тиімді әдісті үйретеміз.

1-әдіс: Электрондық пошта мекенжайы жоқ контактілерді тапқаннан кейін қолмен жою

1. Бастау үшін «Контактілер» тақтасына кіру үшін «Ctrl + 3» пернелерін басыңыз.
2. Содан кейін іздеу жолағын басыңыз.
3. Әрі қарай, пайда болған «Іздеу» лентасында «Барлық контактілер» түймесін басыңыз.
4. Содан кейін «Мекенжайы бар» > «Электрондық пошта мекенжайы бар» түймесін басыңыз.
5. Осыдан кейін іздеу жолағына «Электрондық пошта мекенжайлары ЕМЕС:=[]» шарты қосылады. «ЖОҚ» белгісін алып тастау керек.
6. Одан кейін электрондық пошта мекенжайы жоқ барлық контактілер тізімде болады.
7. Енді іздеу нәтижелерінде контактілерді қолмен таңдауыңыз керек, өйткені контакт топтары да тізімде болуы керек.
8. Соңында, барлық таңдалған контактілерді жою үшін «Del» пернесін басыңыз.

2-әдіс: VBA көмегімен электрондық пошта мекенжайынсыз барлық контактілерді пакеттік жою

1. Алдымен Outlook бағдарламасында VBA редакторын іске қосу үшін «Alt + F11» түймесін түртіңіз.
2. Жаңа экранда келесі VBA кодын модульге көшіріңіз.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Кейінірек «EmailAddressWithoutEmailAddress BatchDeleteAllContacts» ішкі бағдарламасын басыңыз.
4. Соңында осы макросты іске қосу үшін «F5» пернесін басыңыз.
5. Ол аяқталған кезде сіз төмендегі сурет сияқты нәтижелер туралы хабарлама аласыз.
6. Электрондық пошта мекенжайы жоқ барлық контактілер «Жойылған элементтер» қалтасына жылжытылды.

Барлық ықтимал қауіптерден алыс ұстаңыз

Outlook бағдарламасы вирустар, пайдаланушы қателері, бағдарламалық құрал ақаулары, сондай-ақ аппараттық құрал ақаулары сияқты әртүрлі факторларға байланысты зақымдалуы мүмкін. Outlook зақымдалуын сезінгіңіз келмеуі керек, сондықтан осы ықтимал тәуекелдердің барлығын аулақ ұстауыңыз керек. Мысалы, компьютерге күшті антивирустық бағдарламалық құралды орнату керек. Сонымен қатар, Outlook деректерінің сақтық көшірмесін жүйелі түрде жасау керек. Соңғысы, мысалы, берік және сенімді жөндеу құралын дайындағаныңыз жөн DataNumen Outlook Repair. Ол сіздің жағдайыңызды түзете алады сыбайлас PST файлды оңай.

Автордың кіріспесі:

Ширли Чжан - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. SQL Server жемқорлық және бағдарламалық жасақтаманы жөндеу бағдарламалары. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com