Сіздің сөзіңізде белгілі бір мәтін бар сөйлемдерді табудың немесе жоюдың жылдам тәсілдері

Бұл мақалада біз сізге Word бағдарламасында белгілі бір мәтіні бар сөйлемдерді табудың немесе жоюдың 2 жылдам әдісін ұсынамыз.

Word бағдарламасындағы «Табу және ауыстыру» функциясын пайдаланып, белгілі бір сөздердің барлық кездесетін жерлерін оңай табуға болатыны баршаға белгілі. Сонда оларды ерекшелеуде, ауыстыруда немесе жоюда ешқандай қиындық болмайды. Көріп отырғаныңыздай, мақсат - сөз немесе сөз тіркесі. Дегенмен, бүгін біз сізге белгілі бір мәтінді қамтитын сөйлемдерді қалай табуға немесе жоюға болатынын айтып беруге қуаныштымыз.

1-әдіс: Арнайы мәтіні бар сөйлемдерді табу немесе жою

1. Бастау үшін Word бағдарламасындағы VBA редакторын қосу үшін «Alt + F11» пернелерін басыңыз.
2. Әрі қарай «Қалыпты» батырмасын басу арқылы жаңа модуль жасаңыз.
3. Содан кейін «Кірістіру» түймесін басып, жаңасын алу үшін «Модуль» тармағын таңдаңыз.
4. Ал модульді екі рет басу арқылы ашыңыз.
5. Енді келесі кодтарды қойыңыз:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Әрі қарай «Іске қосу» батырмасын басыңыз.
7. Мәтінді енгізуді сұрайтын енгізу өрісі болады. Барлық сөйлемдердегі жалпы мәтінді теріңіз. «OK» түймесін басыңыз.
8. Содан кейін сіз таңдалған мәтінді қамтитын сөйлемді көресіз. Сөйлемді жою үшін «Иә» түймесін және оны сақтау үшін «Жоқ» түймесін басыңыз.
9. Растаудан кейін, белгіленген мәтіні бар келесі сөйлем таңдауда болады. Растау өрісі де бар. Атап айтқанда, макрос сізді бүкіл құжатты қарап шығуға, мақсатты сөйлемдерді табуға және әр жолы растауды сұрауға алып барады.

2-әдіс: тізімдегі кез келген мәтіні бар сөйлемдерді табу немесе жою

1-әдістегі макроспен бір уақытта тек бір сөзді немесе сөз тіркесін іздеуге болады. Әрине, сөздердің немесе сөз тіркестерінің бірнеше данасын табу үшін макросты қайта-қайта іске қосуға болады. Бірнеше рет іздеу қажеттілігін қанағаттандыру үшін біз сізге басқа макросты береміз.

1. Алдымен барлық мақсатты мәтіндерді жаңа құжатқа орналастырыңыз. Әрбір мәтін бөлігінің бір абзацты алып, артында бос орын қалдырмағанына көз жеткізіңіз. Құжатты жауып, сақтаңыз.
2. Келесі 1-әдістегі нақты қадамдармен макросты орнатыңыз және іске қосыңыз.
3. Содан кейін макросты мынамен ауыстырыңыз:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Енді «Шолу» терезесі ашылады. Жаңа ғана сақталған құжатты таңдап, «Ашу» түймесін басыңыз.
5. Келесі процедура 1-әдістегімен бірдей.

Сыбайлас құжаттармен күресу тәсілі

Құнды деректердің жоғалуы мүлдем жойқын. Бұл тіпті сіздің бизнесіңізді қауіпте қалдыруы мүмкін. Мұндай көңілсіздікке жол бермеу үшін сізге а Сөз түзету мүмкіндігінше тезірек құрал. Мұндай құрал құжатты бұзумен күресте жеңуге көмектеседі.

Автордың кіріспесі:

Вера Чен - деректерді қалпына келтіру бойынша сарапшы DataNumen, Соның ішінде деректерді қалпына келтіру технологиялары бойынша әлемдік көшбасшы болып табылатын Inc. Excel бағдарламасын түзетіңіз және pdf бағдарламалық жасақтама өнімдерін жөндеу. Қосымша ақпарат алу үшін кіріңіз WWW.datanumen.com