Come esportare rapidamente il tempo totale trascorso sugli appuntamenti di Outlook in ciascuna categoria di colore

Se desideri creare un rapporto sul tempo totale che dedichi agli appuntamenti in ciascuna categoria di colore, puoi utilizzare il metodo introdotto in questo articolo. Può aiutarti a raggiungere questo obiettivo in tempi rapidi senza dover contare manualmente.

Molti utenti sono abituati a registrare la maggior parte delle loro attività nel calendario di Outlook. Inoltre, per gestirle e distinguerle più facilmente, assegnano a ciascuna una categoria. In questo caso, alcuni utenti vorrebbero generare un report che mostri il tempo totale trascorso sugli elementi del calendario in base alla categoria di colore. Senza dubbio, contare e inserire manualmente questi dati è un'operazione laboriosa. Pertanto, qui condivideremo un metodo che consente di svolgere questa attività con un semplice clic.

Esporta il tempo totale impiegato per gli appuntamenti in ogni categoria di colore

1. In primo luogo, avvia la tua applicazione Outlook.
2. Quindi, dopo essere entrato nella finestra di Outlook, puoi toccare i pulsanti "Alt + F11".
3. Successivamente, avrai accesso alla finestra "Microsoft Visual Basic for Applications".
4. Successivamente, dovrai abilitare la "Libreria oggetti di Microsoft Excel". Puoi farlo cliccando su "Strumenti" > "Riferimenti".
5. Quindi, dovresti trovare e aprire un modulo che non è in uso.
6. Successivamente, è necessario copiare il seguente codice VBA in questo modulo.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Finalmente puoi attivare questa macro, non importa facendo clic sull'icona "Esegui" nella barra degli strumenti o premendo il tasto "F5".
8. Quindi, ti verrà chiesto di selezionare un calendario specifico.
9. Dopo aver selezionato e premuto "OK", la macro continuerà a essere eseguita. Al termine, verrà visualizzato un nuovo file Excel in background.
10. Puoi accedervi. Sembrerà il seguente screenshot:

Tieni d'occhio le potenziali minacce attorno al tuo Outlook

Gli utenti di Outlook dovrebbero fare attenzione a tutti i potenziali rischi, inclusi allegati e-mail sconosciuti, collegamenti incorporati ed errori umani. Altrimenti, il tuo Outlook può essere danneggiato in qualsiasi momento. Inoltre, eseguire regolarmente backup dei dati di Outlook e mantenere uno strumento di riparazione specializzato sono questioni di necessità. DataNumen Outlook Repair è uno degli strumenti di riparazione più consigliati. Può riparare Outlook problemi in un batter d'occhio.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui mdf danneggiato e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com