Come esportare rapidamente le informazioni sulle dimensioni di tutte le cartelle in un file PST in un file Excel

Se desideri controllare le informazioni sulla dimensione di ciascuna cartella in un file PST, puoi utilizzare il metodo esposto in questo articolo. Esporterà rapidamente le informazioni sulle dimensioni di tutte le cartelle in un file PST in un file Excel.

Quando il tuo file PST è troppo grande, potresti voler controllare la dimensione di ogni cartella. Ti aiuterà a capire facilmente quali sono i più grandi e fare un'archiviazione adeguata in base alle dimensioni. In generale, per controllare la dimensione della cartella, puoi semplicemente fare clic con il tasto destro su una cartella e quindi scegliere "Proprietà". Nella nuova finestra di dialogo popup, puoi fare clic sul pulsante "Dimensioni cartella". Tuttavia, se sono state create molte cartelle, controllare manualmente le informazioni sulle dimensioni una per una è notevolmente problematico. Quindi, se si desidera ottenere in batch le informazioni sulla dimensione di tutte le cartelle in un file PST, è possibile utilizzare il seguente codice VBA. Esporterà tutti i nomi delle cartelle e le informazioni sulle dimensioni in un file Excel in una volta sola.

Esporta le informazioni sulle dimensioni di tutte le cartelle in un file PST in un file Excel

1. A start con, avvia l'applicazione Outlook.
2. Quindi passare alla scheda "Sviluppatore" e fare clic sul pulsante "Visual Basic" o premere i tasti "Alt + F11" per accedere all'editor VBA.
3. Avanti nella finestra "Microsoft Visual Basic for Applications", apri un modulo che non è in uso.
4. Successivamente, copia e incolla i seguenti codici VBA in questo modulo.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Successivamente, dovresti impostare il livello di sicurezza delle macro di Outlook su basso.
6. Alla fine, puoi provare.

• Premere il tasto F5 nella finestra della macro corrente.
• Quindi ti verrà chiesto di selezionare un file PST, come la seguente immagine:
• Dopo aver selezionato un file di origine, Outlook inizierà a esportare le informazioni sulle dimensioni in Excel.
• Al termine della macro, ricevi un messaggio come lo screenshot qui sotto.
• Infine, sarai in grado di trovare il file Excel nella cartella locale predefinita. Il file Excel sarà simile al seguente:

Affrontare frequenti errori PST

Poiché Outlook è soggetto a errori, potresti aver mai riscontrato molti problemi in Outlook. Al fine di affrontare meglio e in modo più flessibile i frustranti problemi PST, è consigliabile mantenere un'utilità di correzione esperta e affidabile nelle vicinanze, come DataNumen Outlook Repair. È in grado di correggere PST problemi come un gioco da ragazzi.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui SQL Server recupero e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com