Come esportare rapidamente un'e-mail di Outlook come file immagine

Alcuni utenti desiderano esportare un'e-mail di Outlook come file immagine, ad esempio un file jpg. Pertanto, in questo articolo, ti presenteremo come ottenerlo tramite il codice VBA di Outlook.

Devi aver imparato una serie di trucchi per esportare un'e-mail come file di testo, documento Word e così via. Quindi, che ne dici di esportare un'e-mail come immagine come un file JPG? Apparentemente, Outlook non ha questa funzione. Ma, in seguito, condivideremo con te un mezzo rapido.

Esporta rapidamente un'e-mail di Outlook come file immagine

1. Per cometart, avvia la tua applicazione Outlook.
2. Quindi, nella finestra principale di Outlook, accedi all'editor VBA in conformità con l'articolo: "Come eseguire il codice VBA in Outlook".
3. Successivamente, abilitare "MS Word Object Library" e "MS PowerPoint Oggetto library” facendo riferimento all'articolo – “Come aggiungere un oggetto Library Riferimento in VBA".
4. Successivamente, copia e incolla il seguente codice VBA in un modulo vuoto.

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. Successivamente, è necessario aggiungere la macro alla barra di accesso rapido.
6. Successivamente, puoi chiudere l'editor VBA.
7. Successivamente, seleziona un'e-mail e premi il pulsante macro nella barra di accesso rapido.
8. Al termine della macro, puoi andare alla cartella locale predefinita per trovare il file immagine esportato da questa email.

Recupera i dati di Outlook dal file danneggiato

Potresti essere piuttosto frustrante se il tuo file di Outlook è soggetto a gravi danni. In tale scenario, procederai all'estrazione dei dati di Outlook dal file compromesso. Alcuni utenti tenderanno a utilizzare lo strumento di riparazione della posta in arrivo. Eppure, most di tempo, non produrrà effetti. Pertanto, faresti meglio a mantenere un formidabile e affidabile Correzione PST strumento, come DataNumen Outlook Repair. Può scansionare il file corrotto e recuperare il massimo dei dati senza problemi.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui correzione del mdf e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com