Come esportare rapidamente tutti i collegamenti ipertestuali in più e-mail di Outlook in Excel

Quando devi estrarre tutti i collegamenti ipertestuali da una o più email, copiarli uno per uno è una pessima idea. Questo articolo ti insegnerà un metodo per esportare rapidamente tutti i collegamenti ipertestuali da più email in Excel.

Per alcuni motivi, come la registrazione dei collegamenti ipertestuali in tutte le e-mail inviate, dovrai estrarre i collegamenti ipertestuali. Senza dubbio è sconsigliabile estrarli e copiarli manualmente. Devi desiderare un approccio molto più intelligente, come l'utilizzo di VBA. Qui ti condivideremo un tale pezzo di codice VBA, che è in grado di esportare tutti i collegamenti ipertestuali in molte e-mail in Excel con un semplice clic.

Esporta tutti i collegamenti ipertestuali in più e-mail in Excel

1. Per iniziare, avvia il programma Outlook come di consueto.
2. Quindi, nella finestra di Outlook, devi premere i pulsanti "Alt + F11".
3. Immediatamente, avrai accesso all'editor VBA di Outlook.
4. Successivamente, è necessario abilitare sia "Libreria oggetti di Microsoft Word" che "Libreria oggetti di Microsoft Excel". Fare clic su "Strumenti" > "Riferimenti" e quindi abilitarli nella finestra di dialogo visualizzata.
5. Successivamente, è necessario aprire un modulo inutilizzato, in cui è necessario copiare il codice VBA di seguito in questo modulo.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllHyperlinksInMultipleEmailsToExcel()
    Dim objSelection As Selection
    Dim objMail As MailItem
    Dim objMailDocument As Document
    Dim objHyperlink As Hyperlink
    Dim i As Long
 
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
 
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
       objExcelApp.Visible = True
       objExcelWorkbook.Activate
 
       With objExcelWorksheet
            .Cells(1, 1) = "No."
            .Cells(1, 2) = "Displaying Text"
            .Cells(1, 3) = "Address"
            .Cells(1, 4) = "Source Mail"
      End With
 
      On Error Resume Next
      i = 0
      For Each objMail In objSelection
          objMail.Display
          Set objMailDocument = objMail.GetInspector.WordEditor
          If objMailDocument.Hyperlinks.Count > 0 Then
             For Each objHyperlink In objMailDocument.Hyperlinks
                 If InStr(objHyperlink.Address, "www.") > 0 Then
                    i = i + 1
                    Call ExportToExcel(i, objMail, objHyperlink)
                 End If
             Next
          End If
          objMail.Close olDiscard
      Next
 
      objExcelWorksheet.Columns("A:D").AutoFit
    End If
End Sub

Sub ExportToExcel(n As Long, objCurrentMail As MailItem, objCurrentHyperlink As Hyperlink)
    Dim nLastRow As Integer
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    objExcelWorksheet.Range("A" & nLastRow) = n
    objExcelWorksheet.Range("B" & nLastRow) = objCurrentHyperlink.TextToDisplay
    objExcelWorksheet.Range("C" & nLastRow) = objCurrentHyperlink.Address
    objExcelWorksheet.Range("D" & nLastRow) = objCurrentMail.Subject
End Sub

6. Successivamente, puoi uscire dalla finestra dell'editor VBA corrente.
7. Accedere successivamente a "Opzioni di Outlook" per personalizzare la barra di accesso rapido per aggiungere la macro appena aggiunta alla barra di accesso rapido.
8. Finalmente puoi fare uno scatto:

• Prima di tutto, nell'elenco e-mail, seleziona le e-mail di cui desideri estrarre i collegamenti ipertestuali.
• Quindi, fai clic sul pulsante macro nella barra di accesso rapido.
• Al termine della macro, otterrai un file Excel, come l'immagine qui sotto:

Risolvi i problemi imprevisti di Outlook

I problemi di Outlook possono verificarsi di tanto in tanto senza alcun preavviso. Ma, in termini di piccoli errori, Outlook può essere ripristinato con un semplice riavvio o il suo strumento di riparazione della posta in arrivo. Ma se incontri dei gravi problemi, i mezzi interni non produrranno effetti. A questo punto, la tua ultima risorsa è sicuramente uno strumento più affidabile e robusto, come ad esempio DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui mdf corrotto e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com