Come estrarre rapidamente tutti i destinatari da più file di messaggi di Outlook (.msg).

Alcuni utenti vorrebbero estrarre rapidamente tutti i destinatari da più file di messaggi di Outlook salvati dalle e-mail di Outlook. Ora, questa pagost esaminerà questo per condividere un approccio rapido.

Per estrarre i destinatari da un singolo file di messaggio di Outlook, puoi semplicemente fare doppio clic per aprirlo e quindi copiare i destinatari nella finestra del messaggio aperta. Tuttavia, se è necessario gestire un batch di file di messaggi di Outlook, il metodo manuale non è abbastanza efficiente. Pertanto, potresti cercare un modo molto più efficiente. Qui vi presenteremo tale. Continua a leggere per ottenere i suoi dettagli.

Estrai tutti i destinatari da più file di messaggi di Outlook (.msg).

1. Per cometart, accedi all'editor VBA di Outlook in base a "Come eseguire il codice VBA in Outlook".
2. Successivamente, copia e incolla il seguente codice VBA in un modulo vuoto.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Quindi, sposta il cursore nella prima subroutine.
4. Successivamente, fare clic sul pulsante "Esegui" o premere il tasto "F5".
5. Quindi, nella finestra di dialogo popup, seleziona la cartella Windows che contiene i file dei messaggi di Outlook (.msg) di origine.
6. Dopo aver selezionato, fare clic su "OK" per consentire alla macro di continuare a funzionare.
7. Al termine della macro, verrà visualizzato un messaggio che elenca tutti gli indirizzi e-mail dei destinatari estratti, come mostrato nello screenshot seguente.

Proteggi i tuoi dati di Outlook da pericoli

I dati di Outlook sono certamente soggetti a corruzione. Pertanto, è un compito piuttosto oneroso salvaguardare i dati di Outlook. Richiede di perseverare nel fare backup regolari per i dati di Outlook. Inoltre, se possibile, è prudente e consigliato preparare una prospettiva esperta e professionale Riparazione PST strumento, come DataNumen Outlook Repair, in modo da poter ottenere un salvataggio immediato e tempestivo in caso di danneggiamento di Outlook.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui recuperare Sql Server e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com