Come creare rapidamente un gruppo di contatti da tutti i contatti di Outlook con un titolo di lavoro specifico

Per comunicare più facilmente con i contatti con un titolo di lavoro specifico, potresti voler creare rapidamente un gruppo di contatti da questi contatti. Ora, in questo articolo, condivideremo con te un metodo veloce.

Se invii spesso in batch e-mail, attività o inviti a riunioni ai contatti con un titolo di lavoro specifico, sarà molto più conveniente se crei un gruppo di contatti da loro. Generalmente, nel modo standard, devi prima creare un nuovo gruppo di contatti e poi aggiungere i contatti al gruppo come membri uno per uno. È un po' fastidioso. Pertanto, di seguito ti insegneremo un modo molto più rapido per ottenerlo.

Crea un gruppo di contatti da tutti i contatti con un titolo di lavoro specifico

1. Inizialmente, in una cartella Contatti, seleziona un contatto con il titolo di lavoro specifico.
2. Quindi, premi "Alt + F11" per accedere all'editor VBA di Outlook.
3. Successivamente, copia il seguente codice VBA in un modulo o progetto vuoto.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Successivamente, sposta il cursore nella prima subroutine.
5. Infine, tocca il pulsante "F5" per eseguire questa macro.
6. Al termine della macro, verrà visualizzato un nuovo gruppo di contatti. Contiene tutti i contatti con lo stesso titolo di lavoro del contatto selezionato nel passaggio 1.

Proteggi i dati di Outlook in modo efficace

Sebbene Outlook sia ricco di funzionalità, non può eliminare il fatto che è vulnerabile. Quindi, se non vuoi perdere i tuoi preziosi dati di Outlook, devi fare degli sforzi per proteggerli. Ad esempio, è necessario eseguire backup dei dati di Outlook a intervalli regolari. Inoltre, se conveniente, si consiglia di disporre di uno strumento di riparazione PST all'avanguardia, come ad esempio DataNumen Outlook Repair, Che può riparare PST dati in un batter d'occhio.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui sql corrotto e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com