Come salvare in batch più bozze di email come modelli di Outlook

Forse hai creato diverse bozze di email e speri di riutilizzarle molte volte. In tal caso, perché non li salvi in ​​batch come modelli di Outlook? Questo articolo ti insegnerà a realizzarlo in una volta sola tramite VBA.

Per impostazione predefinita, Outlook consente solo agli utenti di salvare una singola e-mail come modello alla volta. In altre parole, non è possibile salvare più bozze di email come modelli in blocco. Come puoi vedere, quando selezioni più di una mail e vai su "File" > "Salva con nome", non riesci a trovare il formato "Modello di Outlook" nell'elenco "Salva come", è disponibile solo "Solo testo". Ma ti presenteremo come realizzarlo in blocco nei seguenti.

Salva in batch più bozze di email come modelli di Outlook

1. All'inizio, attiva l'editor VBA di Outlook.
2. Nella nuova finestra "Microsoft Visual Basic for Applications", copia e incolla il codice VBA di seguito.

Sub SaveMultipleDraftsAsTemplates()
    Dim objSelection As Outlook.Selection
    Dim i As Long
    Dim strTemplateFolder As String
    Dim objMail As Outlook.MailItem
    Dim strSubject As String
 
    'Get all selected mails
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
 
    If Not (objSelection Is Nothing) Then
       'Get the default folder for saving Outlook Templates
       strTemplateFolder = CStr(Environ("USERPROFILE")) & "\Documents\UserTemplates\"
 
       'Save each mail as template
       For i = objSelection.Count To 1 Step -1
           If objSelection(i).Class = olMail Then
              Set objMail = objSelection(i)
              If objMail.Subject <> "" Then
 
                 'Remove unsupported characters
                 strSubject = objMail.Subject
                 strSubject = Replace(strSubject, "/", " ")
                 strSubject = Replace(strSubject, "\", " ")
                 strSubject = Replace(strSubject, ":", "")
                 strSubject = Replace(strSubject, "?", " ")
                 strSubject = Replace(strSubject, Chr(34), " ")
 
                 objMail.SaveAs strTemplateFolder & strSubject & ".oft", olTemplate
              Else
                 objMail.SaveAs strTemplateFolder & "Template" & i & ".oft", olTemplate
              End If
           End If
       Next
 
       'Open the folder of Templates
       Shell "Explorer.exe" & " " & strTemplateFolder, vbNormalFocus
    End If
End Sub

3. Successivamente, per comodità successiva, si consiglia di allegare questa macro alla barra di accesso rapido (QAT). A proposito di passaggi dettagliati, puoi leggere "Come eseguire il codice VBA in Outlook"
4. In definitiva, puoi scattare una foto seguendo le operazioni seguenti.

• Innanzitutto, seleziona le bozze di email da salvare come modelli.
• Quindi, fai clic sul pulsante macro nel QAT.
• Al termine della macro, verrà visualizzata la cartella Windows per il salvataggio dei modelli predefiniti di Outlook. Puoi vedere che i modelli delle bozze di email selezionate sono laggiù.

Lo strumento di riparazione della posta in arrivo può ancora fallire

Quando si tratta dello strumento di correzione interno di Outlook, Scanpst, un gran numero di utenti lo apprezzerà. Indubbiamente, questa utility è davvero in grado di risolvere la maggior parte dei piccoli problemi in Outlook. Tuttavia, non è del tutto impeccabile. Può ancora fallire e far apparire molti errori. Ad esempio, in caso di grave Corruzione di Outlook, non è in grado di riparare il file PST compromesso. In quello scenario, non hai altra alternativa che utilizzare uno strumento di terze parti più potente e di punta, come ad esempio DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui ripristino sql e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com