Come esportare in batch foto e informazioni di più contatti con Outlook VBA

Se desideri estrarre le foto dei contatti e le loro informazioni primarie in una cartella sul tuo disco locale in batch, devi utilizzare Outlook VBA. Questo articolo ti insegnerà come raggiungerlo in dettaglio.

Outlook consente di esportare le informazioni di contatto tramite la funzione "Importa ed esporta". Puoi andare su "File" > "Stampa" > "Importa" > "Esporta in un file".

Tuttavia, questa funzione non ti consente di esportare le foto dei contatti. Pertanto, se desideri estrarre sia le informazioni di contatto che le foto, devi ricorrere a Outlook VBA. Di seguito sono riportati i codici e i passaggi VBA che possono salvare le foto dei contatti in una cartella locale specificata ed estrarre le informazioni di contatto in un file di testo.

Esporta in batch foto e informazioni di più contatti

1. In primo luogo, avvia Outlook e premi i tasti "Alt + F11".
2. Quindi avrai accesso all'editor VBA. Ora dovresti aprire un modulo che non è in uso o creare un nuovo modulo da “Inserisci” > “Modulo”.
3. Successivamente, copia e incolla i seguenti codici VBA nel nuovo modulo.

Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

Attenzione: I codici sopra esporteranno le foto e le informazioni dei contatti nella cartella dei contatti predefinita. È possibile modificare i contatti specificati.

• Se si desidera esportare le foto e le informazioni dei contatti nella cartella attualmente aperta, è necessario sostituire "Set objContacts = ….." con:

Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items

• Se speri solo di esportare le foto e le informazioni dei contatti selezionati, puoi utilizzare le seguenti righe:

Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection

4. Successivamente, puoi chiudere l'editor VBA e procedere con l'aggiunta del nuovo progetto alla barra degli strumenti di accesso rapido come al solito.
5. Infine puoi fare clic sul pulsante macro nella barra di accesso rapido. Immediatamente, le foto e le informazioni del contatto verranno esportate nella cartella specificata nel disco locale.

Puoi aprire un file di testo, in cui verranno elencate le informazioni primarie, come il seguente screenshot:

Gestire la corruzione imprevista di Outlook

È un fatto indiscusso che Outlook è vulnerabile. Quindi, se soffri di corruzione di Outlook, quello che dovresti fare prima è calmarti. Quindi puoi continuare a riparare il file e-mail PST di Outlook corrotta. Puoi utilizzare lo strumento di riparazione della posta in arrivo per provare. Se fallisce, non hai altra scelta che utilizzare uno strumento molto più potente, come ad esempio DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui riparare il database SQL mdf danneggiato e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com