Come annullare in batch tutte le riunioni di Outlook programmate in un intervallo di date specifico

Se desideri annullare tutte le riunioni programmate in un intervallo di date specifico in Outlook, puoi utilizzare i mezzi introdotti in questo articolo. Può salvarti dalla ricerca e dall'annullamento di tali riunioni manualmente.

Se, per qualche motivo, non puoi organizzare o partecipare alle riunioni che si terranno in un determinato intervallo di date future, potresti voler cancellare tutte queste riunioni. Generalmente, devi prima scoprirli e poi cancellarli uno per uno. Sarà abbastanza fastidioso. Pertanto, di seguito, ti condivideremo un altro modo, che è molto più conveniente.

Batch Annulla tutte le riunioni pianificate in un intervallo di date specifico

1. Innanzitutto, avvia il programma Outlook.
2. Quindi, in Outlook, è necessario premere i pulsanti "Alt + F11".
3. Successivamente, entrerai nella finestra "Microsoft Visual Basic for Applications".
4. In questa finestra, dovresti aprire un modulo inutilizzato o semplicemente inserirne uno nuovo.
5. Successivamente, puoi copiare il seguente codice VBA in questo modulo.

Sub BatchCancelAllMeetingsInSpecificDateRange()
    Dim dStartDate As Date
    Dim dEndDate As Date
    Dim objCalendarFolder As Outlook.folder
    Dim objItems As Outlook.Items
    Dim objItemsInDateRange As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim objResponse As Outlook.MeetingItem
 
    'Specify the start date and end date
    dStartDate = InputBox("Enter the start date:", , "10/1/2017")
    dEndDate = InputBox("Enter the end date:", , "10/8/2017")
 
    If dStartDate <> #1/1/4501# And dEndDate <> #1/1/4501# Then
       'Select a calendar folder
       Set objCalendarFolder = Outlook.Application.Session.PickFolder
       Set objItems = objCalendarFolder.Items
       objItems.IncludeRecurrences = True
       objItems.Sort "[Start]"
 
       'Get the appointments in the specific date range
       strFilter = "[Start] >= " & Chr(34) & dStartDate & " 00:00 AM" & Chr(34) & " AND [End] <= " & Chr(34) & dEndDate & " 11:59 PM" & Chr(34)
       Set objItemsInDateRange = objItems.Restrict(strFilter)
 
       objItemsInDateRange.Sort "[Start]"
       For Each objAppointment In objItemsInDateRange
           'Cancel the meetings in this date range
           If objAppointment.MeetingStatus = olMeeting Then
              If objAppointment.Organizer = Outlook.Session.CurrentUser Then
                 objAppointment.MeetingStatus = olMeetingCanceled
                 objAppointment.Save
                 objAppointment.Send
                 objAppointment.Delete
              Else
                 Set objResponse = objAppointment.Respond(olMeetingDeclined)
                 objResponse.Send
                 objAppointment.Delete
              End If
            End If
       Next
    End If
End Sub

6. Alla fine, potresti eseguire questa macro in questo momento.

• Nella finestra macro corrente, premere il tasto "F5".
• Successivamente, ti verrà richiesto di specificare l'intervallo di date.
• Successivamente, verrà visualizzata un'altra finestra di dialogo, che richiede di scegliere una cartella del calendario di origine e fare clic su "OK".
• Infine, al termine della macro, è possibile vedere che tutte le riunioni nell'intervallo di date specifico sono state annullate.
• Nella cartella "Posta inviata", puoi trovare gli annullamenti della riunione, come lo screenshot qui sotto:

Correggi gli errori di Outlook

Se hai utilizzato Outlook per decenni, devi aver riscontrato diversi errori. Fortunatamente Outlook viene fornito con uno strumento di riparazione integrato: Scanpst. Puoi usarlo per riparare Outlook errori. Tuttavia, se fallisce, la tua ultima risorsa sono strumenti di correzione esterni come DataNumen Outlook RepairPuò analizzare i file di Outlook e correggere la maggior parte degli errori, e persino ripristinare facilmente i dati di Outlook danneggiati.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui correggere sql e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com