Come disattivare automaticamente i collegamenti ipertestuali nelle e-mail di Outlook in arrivo da mittenti sconosciuti

Per bloccare i collegamenti dannosi, è meglio configurare Outlook per disabilitare automaticamente i collegamenti ipertestuali nelle e-mail in arrivo da mittenti sconosciuti. Questo articolo rivelerà un codice VBA che può aiutarti a ottenerlo come un tappo di sughero.

Molti utenti si sono lamentati del fatto che i virus trasmessi tramite e-mail hanno attaccato il loro file di Outlook. Il più delle volte, è perché si fidano prontamente di quelle e-mail da mittenti sconosciuti. Quindi scaricano o fanno clic sui collegamenti ipertestuali nelle e-mail. Ora, in seguito, condivideremo un metodo. È in grado di consentire a Outlook di disabilitare automaticamente i collegamenti ipertestuali delle e-mail in arrivo da mittenti sconosciuti. Se hai tali esigenze, continua a leggere per ottenere maggiori dettagli.

Disabilita automaticamente i collegamenti ipertestuali nelle e-mail in arrivo da mittenti sconosciuti

1. Innanzitutto, in Outlook, apri l'editor VBA premendo "Alt + F11".
2. Successivamente, nella nuova schermata, aggiungi l'oggetto "Espressioni regolari MS VBScript" come da post "Come aggiungere un riferimento a una libreria di oggetti in VBA".
3. Quindi, copia e incolla il seguente codice nel progetto "ThisOutlookSession".

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. Dopodiché, attiva questa macro riavviando Outlook oppure premendo il tasto "F5" nella subroutine "Application_Startup".
5. Da allora, ogni volta che un'e-mail proveniente dal mittente che non è archiviata nella cartella Contatti predefinita entra in Posta in arrivo, Outlook disabiliterà automaticamente i collegamenti ipertestuali al suo interno.

Diverse questioni di necessità nella protezione di Outlook

Poiché Outlook è soggetto a danni, è piuttosto difficile salvaguardare il file di Outlook. Qui elencheremo diversi must-have durante la protezione dei dati di Outlook. Prima di tutto, devi eseguire regolarmente il backup dei dati di Outlook. Inoltre, è essenziale fare attenzione a tutti i potenziali rischi, come allegati dannosi o collegamenti ipertestuali. Ultimo ma non meno importante, dovresti preparare in anticipo un potente strumento di correzione di Outlook, come DataNumen Outlook Repair. Ti tornerà sicuramente utile quando ne avrai bisogno riparare PST file ma lo strumento di riparazione della posta in arrivo si rivela un fallimento.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui mdf danneggiato e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com