Metodi 3 per importare e-mail da una cartella di Windows in Outlook

Forse hai salvato diverse e-mail di Outlook nella cartella di Windows. Ora, se vuoi reimportarli in una cartella di Outlook, come puoi farlo? Questo articolo ti insegnerà 3 modi.

Come tutti sappiamo, Outlook fornisce un'opzione integrata: "Salva con nome", con la quale è possibile salvare le e-mail nella cartella di Windows. Tuttavia, non è possibile aggiungere nuovamente le e-mail esportate alla cartella di Outlook. Pertanto, se desideri reimportare le e-mail di Outlook in Outlook, come puoi realizzarlo? Di seguito, ti insegneremo 3 metodi. Puoi sceglierne uno secondo le tue preferenze.

Metodo 1: trascina e rilascia per importare

1. All'inizio, è necessario accedere alla cartella Windows di origine che memorizza le e-mail di Outlook da importare in Outlook.
2. Quindi, avvia l'applicazione Outlook.
3. Quindi apri la cartella di Outlook in cui desideri importare le e-mail.
4. Successivamente, è necessario restringere sia la finestra della cartella di Windows che la finestra di Outlook fino a quando non è possibile visualizzarle nel frattempo.
5. Successivamente, nella cartella Windows, puoi selezionare una delle e-mail di Outlook e quindi premere "Ctrl + A" per selezionarle tutte.
6. Successivamente puoi trascinare e rilasciare le e-mail selezionate nella cartella visibile di Outlook, come nella seguente schermata:
7. Infine, vedrai che tutte le email di Outlook sono state importate dalla cartella Windows alla cartella di Outlook, mostrata come l'immagine qui sotto:

Metodo 2: utilizzare "CreateItemFromTemplate" in VBA

1. Per iniziare, nella finestra principale di Outlook, premi i tasti “Alt + F11”.
2. Successivamente avrai accesso alla finestra dell'editor VBA di Outlook.
3. Quindi copia il seguente codice VBA in un modulo vuoto.

Sub ImportAllOutlookEmailsfromLocaltoOutlook1()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
  
        If strFileType = "msg" Then
           Set objItem = Outlook.Application.CreateItemFromTemplate(objFile.Path)
 
           objItem.Move objTargetFolder
           'Delete the source file in the Windows folder
           'objFileSystem.DeleteFile (objFile.Path)
        End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

4. Successivamente, nella finestra del modulo corrente, è possibile premere il tasto F5 per avviare la macro.
5. Successivamente, è necessario accedere alla cartella Windows di origine nella finestra di dialogo popup.
6. Infine, dopo aver selezionato la cartella di origine, tutti gli elementi di Outlook in quella cartella verranno importati nella cartella predefinita di Outlook.
7. Nota: in questo modo, le email importate sono tutte email nuove, che puoi comporre a tuo piacimento, come nel seguente screenshot:

Metodo 3: utilizzare "OpenSharedItem" in VBA

1. Come il metodo 2, copia i seguenti codici VBA in un altro modulo.

Sub ImportAllOutlookEmailsfromLocaltoOutlook2()
    Dim objFileSystem As Object
    Dim strLocalFolderPath As String
    Dim objLocalFolder As Object
    Dim objTargetFolder As Outlook.Folder
    Dim objFiles As Object
    Dim objFile As Object
    Dim strFileType As String
    Dim objItem As Object
    Dim objCopiedItem As Outlook.MailItem

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    strLocalFolderPath = strSelectedFolder("")
    Set objLocalFolder = objFileSystem.GetFolder(strLocalFolderPath)
    Set objFiles = objLocalFolder.Files
 
    'Set the target Outlook folder
    Set objTargetFolder = Session.GetDefaultFolder(olFolderInbox).folders("Ago")
 
    For Each objFile In objFiles
        strFileType = objFileSystem.GetExtensionName(objFile)
 
        If strFileType = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)
           'Only import emails
           If TypeOf objItem Is MailItem Then
              Set objCopiedItem = objItem.Copy
              objCopiedItem.Move objTargetFolder
              'Delete the source file in the Windows folder
              'objFileSystem.DeleteFile (objFile.Path)
           End If
       End If
    Next
End Sub

Function strSelectedFolder(strStartFolder As String) As String
    Dim objShell As Object
    Dim objFolder As Object
 
    On Error Resume Next
    Set objShell = CreateObject("Shell.Application")
    Set objFolder = objShell.BrowseForFolder(0, "Select the source folder:", 0, strStartFolder)
 
    strSelectedFolder = objFolder.self.Path
End Function

2. Quindi eseguire questa macro premendo il tasto "F5".
3. Quindi selezionare la cartella di origine.
4. Alla fine tutte le email verranno importate come l'immagine qui sotto:

Confronti

Mezzi per bloccare la corruzione dei dati PST

Come tutti sappiamo, Outlook viene preinstallato con uno strumento integrato: ScansioneNella maggior parte dei casi, è in grado di risolvere piccoli problemi. Tuttavia, se i problemi sono estremamente gravi, lo strumento integrato tenderà a fallire. Quindi, è meglio ricorrere a uno strumento più potente, come DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui SQL Server corruzione e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com