2 modi rapidi per esportare l'elenco di tutte le e-mail di Outlook contrassegnate in Excel

Se desideri esportare l'elenco di tutte le email contrassegnate dalla tua casella di posta di Outlook in Excel, puoi utilizzare uno dei 2 metodi condivisi in questo articolo.

Ad esempio, per gestire più tempestivamente tutte le e-mail contrassegnate o condividerle con qualcun altro, potresti sperare di esportarle in un foglio di lavoro Excel. Qui introdurremo 2 approcci per realizzarlo. Il primo utilizza la funzione standard "Importa ed esporta" dopo aver trovato le email contrassegnate. Ad essere onesti, è un po' noioso. Pertanto, in quest'ultimo, ti insegneremo un modo più conveniente che applica VBA.

Metodo 1: esporta manualmente tutte le e-mail contrassegnate trovate

1. Prima di tutto, fai clic sulla casella di ricerca sopra l'elenco di posta.
2. Quindi, fai clic su "Tutti gli elementi di posta" nel gruppo "Ambito" nella scheda "Cerca".
3. Successivamente, fai clic sul pulsante "Contrassegnato" nel gruppo "Definisci".
4. Dopo aver visualizzato tutte le e-mail contrassegnate nell'elenco, seleziona una e-mail e premi "Ctrl + A" per selezionarle tutte.
5. Quindi, premi le scorciatoie da tastiera "Ctrl + Maiusc + V".
6. Nella nuova finestra di dialogo, crea una nuova cartella sotto il file di Outlook.
7. Successivamente, seleziona la nuova cartella creata e fai clic su "OK", che sposterà tutte le e-mail contrassegnate trovate nella nuova cartella.
8. Successivamente, fare clic su “File” > “Apri” > “Importa”,
9. Nella finestra di dialogo popup, scegli "Esporta in un file" > "Avanti" > "Microsoft Excel 97-2003" > "Avanti".
10. Nella nuova schermata, seleziona la cartella corretta e premi "Avanti".
11. Successivamente, segui le procedure guidate per completare "Esporta".
12. Otterrai un nuovo file Excel, mostrato come la seguente schermata.

Metodo 2: Esporta l'elenco di tutte le email contrassegnate tramite VBA

1. In Outlook, premi "Alt + F11" per attivare l'editor VBA.
2. Quindi, abilitare "Oggetto MS Excel" in conformità a "Come aggiungere un riferimento a una libreria di oggetti in VBA".
3. Quindi, copia il codice VBA di seguito in un modulo.

Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportAllFlaggedEmailsToExcel()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
  
    'Select a source PST file
    Set objOutlookFile = Outlook.Application.Session.PickFolder
 
    If Not (objOutlookFile Is Nothing) Then
       'Create a new Excel file
       Set objExcelApp = CreateObject("Excel.Application")
       Set objExcelWorkbook = objExcelApp.Workbooks.Add
       Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
       objExcelApp.Visible = True
 
       With objExcelWorksheet
           .Cells(1, 1) = "Subject"
           .Cells(1, 1).Font.Bold = True
           .Cells(1, 2) = "Start Date"
           .Cells(1, 2).Font.Bold = True
           .Cells(1, 3) = "Due Date"
           .Cells(1, 3).Font.Bold = True
           .Cells(1, 4) = "From"
           .Cells(1, 4).Font.Bold = True
           .Cells(1, 5) = "To"
           .Cells(1, 5).Font.Bold = True
      End With
 
      For Each objFolder In objOutlookFile.Folders
          If objFolder.DefaultItemType = olMailItem Then
             Call ProcessMailFolders(objFolder)
          End If
      Next
 
      objExcelWorksheet.Columns("A:E").AutoFit

      MsgBox "Completed!", vbInformation + vbOKOnly, "Export Emails"
    End If
End Sub

Sub ProcessMailFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objFlaggedMail As Outlook.MailItem
    Dim nLastRow As Integer
    Dim objSubfolder As Outlook.Folder
 
    For i = 1 To objCurrentFolder.Items.Count
        If objCurrentFolder.Items(i).Class = olMail Then
           'Export the information of each flagged email to Excel
           Set objMail = objCurrentFolder.Items(i)
           If objMail.IsMarkedAsTask = True And objMail.FlagStatus <> olFlagComplete Then
              Set objFlaggedMail = objMail
 
              With objExcelWorksheet
                   nLastRow = .Range("A" & .Rows.Count).End(xlUp).Row + 1
                   .Range("A" & nLastRow) = objFlaggedMail.Subject
                   .Range("B" & nLastRow) = objFlaggedMail.TaskStartDate
                   .Range("C" & nLastRow) = objFlaggedMail.TaskDueDate
                   .Range("D" & nLastRow) = objFlaggedMail.SenderName
                   .Range("E" & nLastRow) = objFlaggedMail.To
              End With
          End If
        End If
    Next i
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessMailFolders(objSubfolder)
       Next
    End If
End Sub

4. Infine, posiziona il cursore nella subroutine "ExportAllFlaggedEmailsToExcel" e premi il pulsante "F5".
5. Quindi, seleziona un file di Outlook nella nuova finestra di dialogo.
6. Quando ricevi il prompt "Completato", otterrai anche un nuovo file Excel, come l'immagine qui sotto.

Proteggi il tuo Outlook dalla corruzione

Outlook è soggetto a errori e danneggiamenti, quindi proteggere i dati di Outlook è un compito molto arduo. Indubbiamente, il modo più efficace e pratico è quello di effettuare backup regolari dei dati di Outlook. Inoltre, è anche necessario procurarsi uno strumento di riparazione di Outlook potente e affidabile, come DataNumen Outlook Repair. Tornerà utile se strumento di riparazione della posta in arrivo non fa alcun effetto.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui fisso SQL Server e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com