Metodi 2 per eliminare in batch tutti i contatti senza indirizzo e-mail in Outlook

Se noti che alcuni contatti in Outlook non hanno un indirizzo email, potresti voler elaborare ogni cartella Contatti per eliminare tutti questi contatti. Questo articolo ti mostrerà due metodi.

Forse hai molti contatti nel tuo Outlook e alcuni di loro non hanno un indirizzo email. Se pensi che non siano più utili, devi sperare di eliminare tutti i contatti senza indirizzo email. Nel modo standard, puoi utilizzare "Ricerca istantanea" per trovarli e quindi eliminarli manualmente, come il seguente Metodo 1. Tuttavia, è un po' noioso. Pertanto, nel Metodo 2, ti insegneremo un altro modo più efficiente.

Metodo 1: Elimina manualmente dopo aver trovato i contatti senza indirizzo e-mail

1. Per iniziare, premi i tasti “Ctrl + 3” per accedere al riquadro “Contatti”.
2. Quindi, fai clic nella casella di ricerca.
3. Successivamente, nella barra multifunzione emergente "Cerca", fai clic su "Tutti gli elementi di contatto".
4. Successivamente, fai clic su "Ha indirizzo" > "Ha indirizzo e-mail".
5. Successivamente, il criterio "NON indirizzi e-mail:=[]" verrà aggiunto nella casella di ricerca. Devi rimuovere il "NON".
6. Successivamente verranno elencati tutti i contatti privi di indirizzo email.
7. Ora, dovresti selezionare manualmente i contatti nei risultati della ricerca in quanto anche i tuoi gruppi di contatti devono essere nell'elenco.
8. Infine, premi il tasto "Del" per eliminare tutti i contatti selezionati.

Metodo 2: elimina in batch tutti i contatti senza indirizzo e-mail con VBA

1. All'inizio, tocca "Alt + F11" per avviare l'editor VBA in Outlook.
2. Nella nuova schermata, copia il seguente codice VBA in un modulo.

Sub BatchDeleteAllContactsWithoutEmailAddress()
    Dim objStore As Outlook.Store
    Dim lTotalCount As Long
 
    lTotalCount = 0
    'Process all stores in your Outlook
    For Each objStore In Application.Session.Stores
       Call ProcessContactFolders(objStore.GetRootFolder.Folders, lTotalCount)
    Next
 
    MsgBox lTotalCount & " contacts are deleted!", vbInformation + vbOKOnly, "Delete Contacts"
End Sub

Sub ProcessContactFolders(ByVal objFolders As Outlook.Folders, lCount As Long)
    Dim objFolder As Outlook.Folder
    Dim i As Long
    Dim objContact As Outlook.ContactItem
    Dim objSubfolder As Outlook.Folder

    For Each objFolder In objFolders
        If (objFolder.DefaultItemType = olContactItem) And (objFolder.Name <> "Skype Contacts") Then
           For i = objFolder.Items.Count To 1 Step -1
               If objFolder.Items(i).Class = olContact Then
                  Set objContact = objFolder.Items(i)
                  'Delete the contact w/o email address
                  If (objContact.Email1Address = "") And (objContact.Email2Address = "") And (objContact.Email3Address = "") Then
                     objContact.Delete
                     lCount = lCount + 1
                  End If
               End If
           Next
 
           'Process subfolders recursively
           If objFolder.Folders.Count > 0 Then
              Call ProcessContactFolders(objFolder.Folders, lCount)
           End If
       End If
    Next
End Sub

3. Successivamente, fai clic sulla subroutine "BatchDeleteAllContactsWithoutEmailAddress".
4. Alla fine, premi "F5" per attivare questa macro.
5. Al termine, riceverai un messaggio sui risultati, come l'immagine qui sotto.
6. Tutti i contatti senza indirizzo email sono stati spostati nella cartella "Posta eliminata".

Stai lontano da tutti i potenziali rischi

Outlook può essere danneggiato a causa di una varietà di fattori, come virus, errori dell'utente, guasti del software e guasti hardware. Devi essere riluttante a subire danni di Outlook, quindi devi tenere a bada tutti questi potenziali rischi. Ad esempio, devi montare un potente software antivirus sul tuo PC. Inoltre, devi eseguire regolarmente il backup dei dati di Outlook. Ultimo ma non meno importante, faresti meglio a preparare uno strumento di riparazione robusto e affidabile, come ad esempio DataNumen Outlook Repair. Può aggiustare il tuo PST corrotto file con facilità.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui SQL Server corruzione e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com