2 metodi per stampare rapidamente tutte le tabelle nell'e-mail di Outlook

Se desideri stampare rapidamente tutte le tabelle senza gli altri testi in un'e-mail di Outlook, puoi utilizzare uno dei 2 approcci per farlo.

Quando ricevi un'e-mail che contiene molte tabelle nel corpo del messaggio, a volte potresti desiderare di estrarre queste tabelle e stamparle solo, senza i testi nel corpo. Tuttavia, Outlook non ha funzioni correlate per raggiungerlo. Pertanto, di seguito, ti condivideremo 2 mezzi.

Metodo 1: stampa tutte le tabelle in pagine separate

1. A start con, avvia il tuo programma Outlook.
2. Quindi, nella finestra principale di Outlook, premi i pulsanti "Alt + F11".
3. Nella successiva finestra "Microsoft Visual Basic for Applications", puoi trovare e aprire un modulo che non è in uso.
4. Successivamente, dovresti copiare il seguente codice VBA in questo modulo.

Sub PrintAllTables_inOutlookEmail_Individually()
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objTable As Word.Table
    Dim lTableCount As Long
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim i As Long
 
    'Get the Source Mail
    Set objMail = Outlook.Application.ActiveExplorer.Selection.Item(1)
    Set objMailDocument = objMail.GetInspector.WordEditor
    lTableCount = objMailDocument.Tables.count
 
    Set objWordApp = CreateObject("Word.Application")
    objWordApp.Visible = True
 
    For i = 1 To lTableCount
        Set objTable = objMailDocument.Tables(i)
        objTable.Range.Copy
 
        'Copy Each Table into Each Word Document
        Set objWordDocument = objWordApp.Documents.Add
        objWordDocument.Content.Paste
 
        'Print Out Each Document
        objWordDocument.PrintOut
 
        objWordDocument.Close False
    Next
 
    objWordApp.Quit
End Sub

5. Successivamente dovresti aggiungere il nuovo progetto VBA alla barra degli strumenti di accesso rapido. Vai su "Opzioni di Outlook"> scheda "Barra di accesso rapido" per ottenerlo.
6. Finalmente puoi sparare.

• Innanzitutto, seleziona un'e-mail che contenga diverse tabelle.
• Quindi fare clic sul nuovo pulsante macro nella barra di accesso rapido.
• In una sola volta, tutte le tabelle verranno stampate in singole pagine.

Metodo 2: stampa tutte le tabelle in serie

1. In primo luogo, segui i passaggi da 1 a 2 di cui sopra per andare alla finestra "Microsoft Visual Basic for Applications".
2. Quindi accedi a un modulo inutilizzato, in cui devi copiare il seguente codice VBA al suo interno.

Sub PrintAllTables_inOutlookEmail_Continuously()
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objTable As Word.Table
    Dim lTableCount As Long
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objCell As Word.Cell
 
    Set objMail = Outlook.Application.ActiveExplorer.Selection.Item(1)
    Set objMailDocument = objMail.GetInspector.WordEditor
 
    'Create a Word Document
    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Add
    objWordDocument.Activate
    objWordApp.Visible = True
 
    For Each objTable In objMailDocument.Tables
        objTable.Range.Copy
 
        'Copy All Tables into One Word Document
        With objWordDocument.Range
             .Collapse wdCollapseEnd
             .PasteSpecial wdPasteRTF
             .Text = vbCrLf
        End With
    Next
 
    'Print out the Word Document
    objWordDocument.PrintOut
    objWordDocument.Close False
    objWordApp.Quit
End Sub

3. Successivamente puoi aggiungere la nuova macro alla barra di accesso rapido.
4. Alla fine selezioni una posta di origine e premi il pulsante macro nella barra di accesso rapido. Immediatamente, tutte le tabelle in questa e-mail verranno copiate in un documento Word, che verrà ora stampato.

Proteggi i dati di Outlook dalla corruzione

Nonostante le numerose funzionalità, Outlook non può sfuggire a errori, arresti anomali e corruzione. Pertanto, una volta che si verifica un arresto anomalo, i dati di Outlook tenderanno a darti un addio. Quindi, per prevenire Corruzione di Outlook, è necessario compiere alcuni sforzi, come bloccare i virus nascosti, continuare a chiudere correttamente Outlook e così via. Inoltre, è prudente procurarsi uno strumento di riparazione esperto, come DataNumen Outlook Repair.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui riparare mdf e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.comc