Cara Cepat Mencetak Semua File di a Zip Lampiran Email Outlook

Banyak pengguna berharap untuk mencetak semua file yang dikompresi dalam format a zip lampiran email Outlook tanpa kesulitan menyimpan dan mendekompres file zip lampiran. Karenanya, artikel ini akan memperkenalkan cara yang jauh lebih efektif untuk mewujudkannya.

Ketika Anda ingin mencetak a zip Jika Anda terbiasa melampirkan file, Anda mungkin sudah terbiasa meletakkannya di atas file tersebut dan mengklik tombol "Cetak Cepat" di pita menu. Namun, dengan cara ini, Outlook tetap akan meminta Anda untuk menyimpan dan mengekstrak file terlebih dahulu. Jika Anda ingin menghindari langkah-langkah yang merepotkan ini, Anda dapat menggunakan kode VBA berikut.

Cetak Semua File dalam a Zip Lampiran Email

1. Pertama-tama, buka aplikasi Outlook Anda.
2. Kemudian, dapatkan akses ke editor Outlook VBA dengan mengikuti langkah-langkah yang ditunjukkan di artikel – “Cara Menjalankan Kode VBA di Outlook Anda".
3. Selanjutnya, Anda dapat membuka proyek “ThisOutlookSession” atau modul yang tidak digunakan.
4. Selanjutnya, salin dan tempel kode VBA di bawah ini.

Dim objShell As Object
Dim objFileSystem As Object

Sub PrintAllFilesInZipAttachment ()
    Dim objAttachmentSelection As Outlook.AttachmentSelection
    Dim objAttachment, objTempAttachment As Outlook.Attachment
    Dim strTempFolder As String
    Dim strSavingPath As String
    Dim objTempMail As Outlook.MailItem
    Dim strFileName As String
 
    'Get selected attachment
    Set objAttachmentSelection = Outlook.Application.ActiveExplorer.AttachmentSelection
    Set objAttachment = objAttachmentSelection.Item(1)

    If Right(LCase(objAttachment.filename), 3) = "zip" Then
 
       'Save & Unzip the zip attachment
       Set objShell = CreateObject("Shell.Application")
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Unzip" & Format(Now, "yyyymmddhhmmss")
       MkDir (strTempFolder)
 
       strSavingPath = strTempFolder & "\" & objAttachment.filename
       objAttachment.SaveAsFile (strSavingPath)
       objShell.NameSpace((strTempFolder)).CopyHere objShell.NameSpace((strSavingPath)).Items
  
       'Attach Unzipped files to a temp mail
       Set objTempMail = Outlook.Application.CreateItem(olMailItem)
       objTempMail.Display
       strFileName = Dir(strTempFolder & "\")
 
       While Len(strFileName) > 0
             objTempMail.Attachments.Add (strTempFolder & "\" & strFileName)
             strFileName = Dir()
       Wend
 
       'Print all attachments of the temp email
       Call PrintFiles(objTempMail)
 
       objTempMail.Close olDiscard
 
       objFileSystem.DeleteFolder (strTempFolder)
    End If
End Sub

Sub PrintFiles(ByVal objMail As Outlook.MailItem)
    Dim objAttachment As Outlook.Attachment
    Dim strTempFolder, strFilePath As String
    Dim objTempFolder As Object
    Dim objTempFolderItem As Object
 
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\TEMP" & Format(Now, "yyyymmddhhmmss")
    MkDir (strTempFolder)
 
    'Print all attachments
    For Each objAttachment In objMail.Attachments
        If Right(LCase(objAttachment.filename), 3) <> "zip" Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile (strFilePath)
 
           Set objShell = CreateObject("Shell.Application")
           Set objTempFolder = objShell.NameSpace(0)
           Set objTempFolderItem = objTempFolder.ParseName(strFilePath)
           objTempFolderItem.InvokeVerbEx ("print")
        End If
    Next
 
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Setelah itu, tutup jendela editor VBA saat ini.
6. Nanti, buka Opsi Outlook untuk menambahkan makro baru ke Bilah Alat Akses Cepat.
7. Terakhir, Anda dapat mengambil bidikan:

• Pertama, pilih a zip lampiran email.
• Lalu, klik makro di Bilah Alat Akses Cepat.

8. Sekaligus, file dikompresi dalam yang dipilih zip lampiran akan dicetak.

Cadangkan File Data Outlook

Anda mungkin telah menemukan bahwa Outlook rentan terhadap kerusakan. Setelah Outlook rusak, data Outlook Anda akan hilang. Oleh karena itu, penting untuk membuat cadangan data Outlook secara teratur, sehingga Anda dapat dengan mudah mengambil kembali data Outlook melalui cadangan. Namun, jika Anda menemukan bahwa cadangan tersebut sudah berusia beberapa minggu dan tidak efektif, Anda tidak punya pilihan selain meminta bantuan kepada penyedia layanan yang andal dan berpengalaman. Pemulihan PST alat, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk mdf rusak dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com