Cara Cepat Mengonversi Semua Gambar yang Tersemat ke Lampiran di Email Outlook Anda

Jika Anda ingin dengan cepat mengubah semua gambar yang disematkan di badan pesan menjadi lampiran email, Anda tidak perlu menghapus dan melampirkan ulang secara manual. Anda bisa menggunakan potongan kode VBA yang terekspos di artikel ini.

Terkadang, Anda mungkin ingin mengubah semua gambar yang disematkan menjadi lampiran. Misalnya, terlalu banyak gambar di badan pesan akan mengganggu pembacaan teks di badan pesan. Oleh karena itu, Anda ingin menghapusnya dari badan email dan menambahkannya sebagai lampiran. Tentu saja, Anda dapat melakukannya secara manual. Tetapi harus lebih mudah jika ada alat atau kode VBA yang bisa mendapatkannya sekaligus. Di sini kami akan mengungkap kode VBA tersebut kepada Anda.

Dengan Cepat Mengonversi Semua Gambar Tersemat ke Lampiran

1. Pertama-tama, start program Outlook Anda.
2. Kemudian Anda dapat beralih ke tab "Pengembang" dan menekan tombol "Visual Basic".
3. Selanjutnya Anda akan masuk ke jendela editor Outlook VBA.
4. Selanjutnya, Anda perlu menyalin kode VBA berikut ke dalam modul kosong.

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Setelah itu, Anda harus mengonfirmasi bahwa Outlook Anda disetel untuk memperbolehkan makro.
6. Secara opsional, jika Anda sering memerlukan ini, sebaiknya Anda menambahkan makro baru ke Bilah Alat Akses Cepat untuk pemeriksaan yang nyaman di masa mendatang.
7. Akhirnya Anda bisa mencobanya. Pilih atau buka email lalu jalankan makro dengan mengklik tombol makro baru di Bilah Alat Akses Cepat.
8. Segera, semua gambar yang disematkan akan diubah menjadi lampiran seperti tangkapan layar berikut:

Trik untuk Melindungi Data Outlook Berharga Anda

Seperti yang kita semua tahu, file PST Outlook sama rentannya dengan file umum, seperti dokumen Word atau spreadsheet Excel. Oleh karena itu, Anda harus tetap waspada terhadap semua risiko di sekitar file PST Anda, seperti virus atau penanganan yang tidak tepat. Jadi, Anda perlu membuat cadangan data reguler untuk file PST Anda. Juga, jika Anda mampu membelinya, adalah bijaksana untuk tetap kuat Perbaikan Outlook alat yang berguna, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memulihkan mdf dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com