Cara Cepat Mengekstrak Semua URL dari Email Outlook ke File Teks

Saat menerima email yang berisi beberapa URL penting di badannya, Anda mungkin ingin memasukkan semua URL ke file teks. Maka dari itu, pada artikel kali ini, kami akan memperkenalkan cara cepat mendapatkannya.

Biasanya, untuk mengekstrak URL dari email Outlook ke file teks, Anda harus membuat file teks terlebih dahulu, lalu menyalin URL ke file tersebut secara manual. Anda mungkin berpikir itu terlalu merepotkan dan sedang mencari cara yang lebih efektif. Jika demikian, Anda dapat terus membaca. Di sini kami akan membagikan pendekatan untuk mengekspor semua URL dari email secara berkelompok.

Ekstrak Cepat Semua URL dalam Email ke File Teks

1. Pertama-tama, di Outlook Anda, akses editor VBA sesuai dengan "Cara Menjalankan Kode VBA di Outlook Anda".
2. Kemudian, salin dan tempel kode VBA berikut ke dalam modul yang tidak digunakan.

Sub ExportURLsFromEmail2TextFile ()
    Dim objMail As Outlook.MailItem
    Dim objRegExp As RegExp
    Dim strFolder As String
    Dim objMatchCollection As MatchCollection
    Dim objMatch As Match
    Dim strURL As String
 
    'Get the source mail
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = ActiveExplorer.Selection.Item(1)
    End Select

    'Get URLs using regular expression
    Set objRegExp = New RegExp
    With objRegExp
         .Pattern = "(https?[:]//([0-9a-z=\?:/\.&-^!#$;_])*)"
         .Global = True
         .IgnoreCase = True
    End With
 
    If objRegExp.test(objMail.Body) Then
  
       'Create a new text file
       strTextFile = "E:\Hyperlinks (" & objMail.Subject & ").txt"
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
       Set objTextFile = objFileSystem.CreateTextFile(strTextFile, True)
       objTextFile.WriteLine ("Extracted URLs:" & vbCrLf & vbCrLf)
 
       Set objMatchCollection = objRegExp.Execute(objMail.Body)
       i = 0
       For Each objMatch In objMatchCollection
           strURL = objMatch.SubMatches(0)
           i = i + 1
 
           'Write the URLs to the text file
           objTextFile.WriteLine (i & ". " & strURL & vbCrLf)
       Next
 
       objTextFile.Close
       'Open the text file
       Shell ("notepad.exe " & strTextFile)
    End If
End Sub

3. Setelah itu, tambahkan makro ini ke pita atau Bilah Alat Akses Cepat.
4. Terakhir, lakukan langkah-langkah di bawah ini untuk mencobanya.

• Pertama-tama, pilih atau buka email.
• Lalu, klik tombol makro di pita atau Bilah Alat Akses Cepat.
• Segera, file teks biasa baru akan dibuka, di mana Anda dapat melihat semua UTL yang diekstrak, seperti yang ditunjukkan pada gambar layar berikut.

Waspadai Tautan Berisiko di Email

Setiap hari, Anda dapat menerima semua jenis email di Outlook Anda. Beberapa berasal dari kontak yang dikenal, dan beberapa mungkin berasal dari pengirim yang tidak dikenal. Dalam menghadapi mereka, Anda perlu berhati-hati terhadap email yang tidak dikenal, beberapa di antaranya mungkin membawa tautan yang mencurigakan. Jika Anda membuka tautan, file Outlook Anda mungkin terinfeksi virus. Kemudian, Anda tidak hanya perlu membunuh virus melalui perangkat lunak antivirus, tetapi Anda juga harus memperbaiki file PST yang menderita melalui program yang ampuh. Perbaikan Outlook utilitas, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk SQL Server memperbaiki dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com