Cara Mengekstrak Gambar Tersemat Secara Otomatis dari Email Masuk Tertentu melalui Outlook VBA

Jika Anda ingin Outlook secara otomatis mengekstrak dan menyimpan gambar yang disematkan dari email masuk tertentu, Anda dapat merujuk ke artikel ini. Di sini kami akan mengajari Anda cara mewujudkannya dengan kode VBA.

Beberapa pengguna sering kali perlu mengekstrak gambar yang disematkan dari email masuk tertentu dan menyimpannya ke folder Windows tertentu. Sangat merepotkan untuk melakukannya secara manual setiap saat. Oleh karena itu, banyak yang berharap dapat mempelajari pendekatan yang cepat dan nyaman agar Outlook dapat melakukannya secara otomatis. Sekarang, di sini kami akan membagikan metode seperti itu kepada Anda.

Ekstrak Otomatis Gambar Tersemat dari Email Masuk Tertentu

1. Pertama, luncurkan program Outlook Anda seperti biasa.
2. Kemudian, picu editor Outlook VBA seperti biasa dengan referensi t "Cara Menjalankan Kode VBA di Outlook Anda".
3. Nanti, salin dan tempel kode VBA berikut ke dalam proyek "ThisOutlookSession".

Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

4. Setelah itu, klik ke "Application_Startup ”subrutin.
5. Terakhir, klik tombol "F5" untuk memicu makro ini.
6. Mulai sekarang, setiap kali email baru tertentu masuk ke Inbox, gambar yang disematkan akan disimpan ke folder Windows tertentu, seperti yang ditunjukkan pada gambar layar berikut.

Bersihkan Attachment Besar Secara Teratur

Dianjurkan untuk membersihkan lampiran besar dari Outlook Anda secara teratur. Ini bertujuan untuk menjaga file Outlook Anda dalam ukuran yang sesuai. File Outlook yang lebih besar lebih rentan terhadap kerusakan. Seperti yang Anda ketahui, kerusakan PST cukup sulit untuk ditangani dengan baik. Mungkin Anda akan mencoba memperbaikinya terlebih dahulu melalui alat perbaikan kotak masuk. Namun, di most kasus, itu tidak akan berhasil. Resor Anda hanya khusus Perbaikan PST alat, seperti DataNumen Outlook Repair, atau layanan pemulihan profesional yang relevan.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk memperbaiki mdf dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com