Cara Batch Hapus Lampiran dari Item Kalender Kedaluwarsa di Outlook Anda

Jika Anda ingin menghapus lampiran dari janji temu dan rapat yang sudah ketinggalan zaman di Outlook, Anda dapat membaca artikel ini. Di sini kami akan memperkenalkan Anda bagaimana mewujudkannya sekaligus.

Untuk mengurangi ukuran file Outlook Anda, sangat disarankan untuk membersihkan item lama. Hal ini dapat diwujudkan dengan fitur “AutoArchive” bawaan, yang dapat menghapus item lama secara otomatis secara berkala. Namun, beberapa pengguna hanya ingin menghapus lampiran di item lama tanpa memengaruhi item itu sendiri. Berikut ini, kami akan mengajari Anda untuk menghapus lampiran secara massal dari item kalender lama.

Batch Hapus Lampiran dari Item Kalender Kedaluwarsa

1. Untuk memulainya, akses editor Outlook VBA dengan "Alt + F11".
2. Kemudian, di jendela "Microsoft Visual Basic for Applications", salin kode VBA ke dalam modul.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Setelah itu, klik makro "BatchDeleteAttachmentsOfOldCalendarItems".
4. Terakhir, tekan tombol "F5" untuk menjalankan makro ini.
5. Saat makro selesai, Anda dapat memeriksa semua kalender Outlook Anda.
6. Outlook harus telah menghapus semua lampiran item kalender yang berusia lebih dari 2 bulan.

Mengatasi File Outlook yang Rusak

Pernahkah Anda mengalami korupsi Outlook? Bagaimana Anda biasanya membuangnya? Lebih sering daripada tidak, pertama-tama Anda akan mencoba alat perbaikan kotak masuk – scanpst. Namun, jika terjadi kerusakan serius pada PST, utilitas bawaan tidak dapat membantu Anda. Oleh karena itu, disarankan untuk menyimpan alat pihak ketiga yang lebih berpengalaman dan luar biasa di sekitarnya, seperti DataNumen Outlook Repair.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk perbaikan sql dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com